I also was provided no overlaps in my part 2 example input, so had nothing to go on to problem solve my initial wrong answer. 
Preprocessing input
Source available here.
defmodule AoC.Day.One.Input do
def parse(input_file \\ System.fetch_env!("INPUT_FILE")) do
input_file
|> File.read!()
|> String.split("\n")
end
end
Part 1
Solution
Lazy regex string scanning. Source available here.
defmodule AoC.Day.One.Part.One do
def solve(input) do
input
|> Enum.map(fn string ->
digits =
~r{\d}
|> Regex.scan(string)
|> List.flatten()
{first, last} = {List.first(digits), List.last(digits)}
(first <> last) |> String.to_integer()
end)
|> Enum.sum()
end
end
Part 2
Solution
Metaprogramming literal binary matching into function heads with an accumulator. Source available here.
I handle overlapping by re-prefixing the matched word, minus the leading letter, to the continue parsing the string character-by-character:
String.slice(word, 1..-1) <> rest
This is overkill for the english language, where overlaps can only happen on the last letter, so the parser could just skip to the end:
String.at(at, -1) <> rest
I like to think that my solution is resiliant to spelling changes in the future of the english language, however. We all know it should be spelled "eeight", right?
defmodule AoC.Day.One.Part.Two do
def solve(input) do
input
|> Enum.map(fn string ->
digits = parse(string)
{first, last} = {List.first(digits), List.last(digits)}
(first <> last) |> String.to_integer()
end)
|> Enum.sum()
end
def parse(string) do
string |> do_parse([]) |> :lists.reverse()
end
# 0?
@digits ~w[1 2 3 4 5 6 7 8 9]
for digit <- @digits do
defp do_parse(unquote(digit) <> rest, acc) do
do_parse(rest, [unquote(digit) | acc])
end
end
# zero?
@word_digit_lookup %{
"one" => "1",
"two" => "2",
"three" => "3",
"four" => "4",
"five" => "5",
"six" => "6",
"seven" => "7",
"eight" => "8",
"nine" => "9"
}
for {word, digit} <- @word_digit_lookup do
defp do_parse(unquote(word) <> rest, acc) do
do_parse(unquote(String.slice(word, 1..-1)) <> rest, [unquote(digit) | acc])
end
end
# Abort recursion when out of characters
defp do_parse("", acc), do: acc
# Otherwise, start scan from next character
defp do_parse(<<_char::binary-size(1), rest::binary>>, acc), do: do_parse(rest, acc)
end
