I learned a lot about LED lighting products (which is useful to understand my home installation better too). d50/d65 was a red herring. They are applicable to reflective color whereas LEDs are, of course, emissive.
Hope you enjoy the all new color 0.4.0. There is a bit of math to map the mix of RGB + W or RGB + WW that aims to give the nearest perceptual match but it’s quite possible the math isn’t the most optimal. Feedback definitely welcome. Here are some of the new functions:
Color.LED.RGBW — 4-channel (R, G, B, W)
This is for chips with one fixed-temperature white LED per pixel like WS2814 and SK6812-RGBW.
# 1. Build a pixel from a hex colour for a WS2814 neutral-white strip
{:ok, target} = Color.new("#ffa500") # sRGB orange
pixel = Color.LED.RGBW.from_srgb(target, chip: :ws2814_nw)
# => %Color.LED.RGBW{r: 0.832…, g: 0.162…, b: 0.0, w: 0.252…, white_temperature: 4500, alpha: nil}
# 2. The white LED takes over for achromatic colours
{:ok, white} = Color.new("#ffffff")
pixel = Color.LED.RGBW.from_srgb(white, chip: :ws2814_ww)
# => r, g, b ≈ 0 | w ≈ 1.0 (all light from the warm-white LED)
# 3. Pure saturated red can't use the white LED at all
{:ok, red} = Color.new("#ff0000")
pixel = Color.LED.RGBW.from_srgb(red, white_temperature: 3000)
# => r: 1.0, g: 0.0, b: 0.0, w: 0.0
# 4. Specify the white LED temperature explicitly instead of a chip preset
{:ok, sky} = Color.new("#87ceeb")
pixel = Color.LED.RGBW.from_srgb(sky, white_temperature: 5000)
# 5. Preview what the pixel will actually emit
{:ok, preview} = Color.LED.RGBW.to_srgb(pixel)
Color.to_hex(preview)
# => "#87ceea" (or very close — exact round-trip for most sRGB colours)
# 6. Go all the way to XYZ for analysis
{:ok, xyz} = Color.LED.RGBW.to_xyz(pixel)
Color.LED.RGBWW — 5-channel (R, G, B, WW, CW)
This is for chips with warm-white + cool-white LEDs per pixel like WS2805 and RGB+CCT SK6812 variants. The two whites blend to reach any CCT between them. Hence why these need to be specified.
# 1. Build a pixel for a WS2805 from an sRGB colour
{:ok, target} = Color.new("#ffa500")
pixel = Color.LED.RGBWW.from_srgb(target, chip: :ws2805)
# => %Color.LED.RGBWW{r: …, g: …, b: …, ww: …, cw: …, warm_temperature: 3000, cool_temperature: 6500, alpha: nil}
# 2. A warm target drives mostly the warm-white LED
{:ok, warm} = Color.new([1.0, 0.85, 0.6])
pixel = Color.LED.RGBWW.from_srgb(warm, chip: :ws2805)
# => pixel.ww > pixel.cw
# 3. A cool target drives mostly the cool-white LED
{:ok, cool} = Color.new([0.85, 0.9, 1.0])
pixel = Color.LED.RGBWW.from_srgb(cool, chip: :ws2805)
# => pixel.cw > pixel.ww
# 4. Pure white splits across both whites to land on ~D65
{:ok, white} = Color.new("#ffffff")
pixel = Color.LED.RGBWW.from_srgb(white, chip: :ws2805)
# => ww + cw ≈ 1.0, r, g, b ≈ 0
# 5. Custom warm/cool temperatures (e.g. a 2700 K + 5700 K fixture)
{:ok, target} = Color.new("rebeccapurple")
pixel =
Color.LED.RGBWW.from_srgb(target,
warm_temperature: 2700,
cool_temperature: 5700
)
# 6. Or pass chip_options/1 directly
options = Color.LED.chip_options(:ws2805)
# => [kind: :rgbww, warm_temperature: 3000, cool_temperature: 6500]
{:ok, target} = Color.new("#336699")
pixel = Color.LED.RGBWW.from_srgb(target, options)
# 7. Simulate what the pixel emits
{:ok, preview} = Color.LED.RGBWW.to_srgb(pixel)
Picking the right chip preset
Color.LED.chips()
# => [:sk6812_cw, :sk6812_nw, :sk6812_ww,
# :ws2805, :ws2814_cw, :ws2814_nw, :ws2814_ww]
Color.LED.chip_options(:ws2814_ww)
# => [kind: :rgbw, white_temperature: 3000]
Color.LED.chip_options(:sk6812_cw)
# => [kind: :rgbw, white_temperature: 6500]
Color.LED.chip_options(:ws2805)
# => [kind: :rgbww, warm_temperature: 3000, cool_temperature: 6500]
Writing pixel bytes to a strip
The channel values are linear floats in [0, 1]. For a typical 8-bit addressable strip, scale and round. Its just plain old bitstring composition (gotta love OTP):
defp to_bytes(%Color.LED.RGBW{r: r, g: g, b: b, w: w}) do
<<round(r * 255), round(g * 255), round(b * 255), round(w * 255)>>
end
defp to_bytes(%Color.LED.RGBWW{r: r, g: g, b: b, ww: ww, cw: cw}) do
<<round(r * 255), round(g * 255), round(b * 255),
round(ww * 255), round(cw * 255)>>
end
It seems that the WS2814 datasheet order is typically GRBW, and WS2805 is typically GRB-WW-CW, so you may need to swap the first two bytes to match your specific chip and SPI driver. I’m fine to add a to_bytes/1 (or maybe better named to_bitstring/1) but I’d need guidance on the canonical byte order - or a configurable option.
