AshJsonApi.Error translations

Guy14

Hello community!

Yesterday I tried for a while to translate errors that comes from AshJsonApi controllers (which are AshJsonApi.Error structs, often built from other error structs such as Ash.Error.Changes.InvalidAttribute if I understood well).

What I used to achieve is to take precedence on AshJsonApi errors implemented in the lib, with dumb errors just for the try, such as this one:

defimpl AshJsonApi.ToJsonApiError, for: Ash.Error.Changes.InvalidAttribute do
  def to_json_api_error(error) do
    dbg("HERE")

    %AshJsonApi.Error{
      id: Ash.UUID.generate(),
      status_code: AshJsonApi.Error.class_to_status(error.class),
      code: "panic",
      title: "Panic",
      detail: error.message
      meta: Map.new(error.vars)
    }
  end
end

But the tradoffs of this new implementation are:

I get a compiler warning:

warning: redefining module AshJsonApi.ToJsonApiError.Ash.Error.Changes.InvalidAttribute (current version loaded from _build/dev/lib/ash_json_api/ebin/Elixir.AshJsonApi.ToJsonApiError.Ash.Error.Changes.InvalidAttribute.beam)│16 │ defimpl AshJsonApi.ToJsonApiError, for: Ash.Error.Changes.InvalidAttribute do│ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~│└─ lib/prepair/to_ash_json_api_error.ex:16: AshJsonApi.ToJsonApiError.Ash.Error.Changes.InvalidAttribute (module)

I will lost eventual updates on the own library errors implementation

I do not manage to translate the error message with gettext (no compiler errors / warnings, but the displayed error is not yet the custom one I wrote, so it shows there is a problem in my implementation of the AshJsonApi.ToJsonApiError protocol):

defimpl AshJsonApi.ToJsonApiError, for: Ash.Error.Changes.InvalidAttribute do
  use Gettext, backend: PrepairWeb.Gettext

  def to_json_api_error(error) do
    dbg("HERE")

    %AshJsonApi.Error{
      id: Ash.UUID.generate(),
      status_code: AshJsonApi.Error.class_to_status(error.class),
      code: "panic",
      title: "Panic",
      detail:
        dgettext(
          "errors",
          "must have the @ sign and no spaces"
        ),
      meta: Map.new(error.vars)
    }
  end
end

I’ve searched on solutions but haven’t found one for now. The nearest to my problem thread I’ve read is this one: Translating Ash Error messages but I haven’t found a solution in it.

Does some of you already implemented translations for AshJsonApi errors?

To add more context, I can say for instance that this translations does work for AshErrors (not AshJsonApi) displayed in the Phoenix Liveview frontend:

defmodule Prepair.ValidationMacros do
  defmacro validate_email() do
    quote do
      use Gettext, backend: PrepairWeb.Gettext

      validate match(
                 :email,
                 ~S/^[a-zA-Z0-9_.+-]+@[a-zA-Z0-9-]+.[a-zA-Z0-9-.]+$/
               ) do
        on [:create, :update]
        message dgettext("errors", "must have the @ sign and no spaces")
      end

But I wonder why the AshJsonApi error which comes from the Ash error triggered by that validation doesn’t send a translated error to the API.

3 comments

/ash #gettext #ash-json-api

0 572 3

2026-03-02 20:08:34 UTC

Showing Posts 1 to 3

Show Best Posts
Show All (oldest first)
Show All (newest first)

zachdaniel

Creator of Ash

I’ve pushed to main an improvement to mirror what we have with ash_graphql, which is an error_handler configuration you can set on each domain that would let you intercept and translate errors.

For gettext, you can’t use it in the DSL like that unfortunately. Those values are captured at compile time.

Post #1

Guy14

Hi Zach, thanks a lot for this solution, that sounds great, I’ll give it a try on tomorrow evening

Post #2

Guy14

Just to let you know, it works perfectly for my needs!!

Thanks a lot again And the added doc for Errors is well detailed

And to anyone reading this post later, here is the solution, thanks to the new feature Zach added, that I’m using to translate API errors coming from AshJsonApi (generated) controllers:

# accounts.ex (Ash Domain)

defmodule Prepair.Accounts do
  use Ash.Domain, extensions: [AshJsonApi.Domain]

  json_api do
    routes do
      ...
    end

    error_handler {PrepairWeb.JsonApiErrorHandler, :handle_error, []}
  end

# json_api_error_handler.ex

defmodule PrepairWeb.JsonApiErrorHandler do
  use Gettext, backend: PrepairWeb.Gettext

  def handle_error(error, _context) do
    translated_detail = translate_error_detail(error.detail)
    %{error | detail: translated_detail}
  end

  defp translate_error_detail(detail) when is_binary(detail) do
    Gettext.dgettext(PrepairWeb.Gettext, "errors", detail)
  end

  defp translate_error_detail(detail), do: detail
end

Post #3

— All posts loaded —