Cast_assoc is null?

[Almog]

I’m trying to do belongs_to on my magnets (posts) but it’s also null, cast_assoc is not doing anything. I’m pretty sure I’m just doing something wrong

My magnets (posts) has

belongs_to :user, Magnify.Coherence.User

And when I create a new magnet (post)

def changeset(magnet, attrs) do
    magnet
    |> cast(attrs, [:title, :description, :content, ])
    |> cast_assoc(:user)
    |> validate_required([:title, :description, :content,])
  end 

Anyone have an idea what I’m doing wrong?

[dokuzbir]

Magnet already has user_id no need cast assoc user. If you want to create magnet with user changeset cast_assoc(:magnet)

[Almog]

The user id is still null, it’s not adding anything

[Almog]

I added |> changeset cast_assoc(:magnet) but I get

function Magnify.Magnets.Magnet.search/2 is undefined (module Magnify.Magnets.Magnet is not available)

[dokuzbir]

actually cast_assoc :user should work too but maybe belongs to tables doesn’t have that property

|> cast(attrs, [:title, :description, :content, :user_id # add this])

[Almog]

I just did that and tested,

[Almog]

6 is the new item

[dokuzbir]

Are you creating from html form or iex? Can you show code?

[Almog]

From html, is it possble that I have in the wrong place should this be in the controller?

Here is the form

<div class="card">
    <div class="card-body">
        <%= form_for @changeset, @action, fn f -> %>
            <%= if @changeset.action do %>
                <div class="alert alert-danger">
                    <p>Oops, something went wrong! Please check the errors below.</p>
                </div>
                <% end %>
                    <div class="form-group">
                        <%= label f, :title, class: "control-label" %>
                            <%= text_input f, :title, class: "form-control" %>
                                <%= error_tag f, :title %>
                    </div>

                    <div class="form-group">
                        <%= label f, :description, class: "control-label" %>
                            <%= text_input f, :description, class: "form-control" %>
                                <%= error_tag f, :description %>
                    </div>

                    <div class="form-group" style="display: block; height: 425px;">
                     <div id="editormd" data-read-only="false" data-line-numbers="true">
                        <%= label f, :content, class: "control-label" %>
                            <%= textarea f, :content, class: "" %>
                                <%= error_tag f, :content %>
                        </div>
                    </div>

    </div>
    <div class="card-actionbar">
        <div class="card-actionbar-row">
            <%= link dgettext("cancel", "Cancel"), to: magnet_path(@conn, :index), class: "btn btn-flat btn-default ink-reaction" %>
            <%= submit dgettext("submit", "Submit"), class: "btn btn-primary" %>
        </div>
    </div>
    <% end %>
</div>

And the schema

defmodule Magnify.Magnets.Magnet do
  use Ecto.Schema
  import Ecto.Changeset
  import Ecto.Query, only: [from: 2]


  schema "magnets" do
    field :content, :string
    field :description, :string
    field :title, :string
    belongs_to :user, Magnify.Coherence.User
    many_to_many :fluxes, Magnify.Magnets.Flux, join_through: "magnets_fluxes"

    timestamps()
  end

  @doc false
  def changeset(magnet, attrs) do
    magnet
    |> cast(attrs, [:title, :description, :content, :user_id])
    |> cast_assoc(:user)
    |> validate_required([:title, :description, :content,])
  end

  def search(query, search_term) do
    wildcard_search = "%#{search_term}%"

    from magnet in query,
         where: ilike(magnet.title, ^wildcard_search),
         or_where: ilike(magnet.description, ^wildcard_search)
  end

end

controller

def new(conn, _params) do
    changeset = Magnets.change_magnet(%Magnet{})
    render(conn, "new.html", changeset: changeset)
  end

  def create(conn, %{"magnet" => magnet_params}) do
    case Magnets.create_magnet(magnet_params) do
      {:ok, magnet} ->
        conn
        |> put_flash(:info, "Magnet created successfully.")
        |> redirect(to: magnet_path(conn, :show, magnet))
      {:error, %Ecto.Changeset{} = changeset} ->
        render(conn, "new.html", changeset: changeset)
    end
  end

[dokuzbir]

Youd should update magnet_params from controller.

def create(conn, %{"magnet" => magnet_params}) do
 magnet_params = Map.put(magnet_params, "user_id",  conn.assigns.current_user.id)
    case Magnets.create_magnet(magnet_params) do
      {:ok, magnet} ->
        conn
        |> put_flash(:info, "Magnet created successfully.")
        |> redirect(to: magnet_path(conn, :show, magnet))
      {:error, %Ecto.Changeset{} = changeset} ->
        render(conn, "new.html", changeset: changeset)
    end

[Almog]

That code is wrong, getting a syntax error

[dokuzbir]

I fixed wrongly } instead of )

[Almog]

Thanks that was it and I think it’s working I am getting the following error which I’m guessing it has to do with the user id

Postgrex expected a binary of 16 bytes, got 1. Please make sure the value you are passing matches the definition in your table or in your query or convert the value accordingly.

[Almog]

This is my db object

schema "magnets" do
    field :content, :string
    field :description, :string
    field :title, :string
    belongs_to :user, Magnify.Coherence.User
    many_to_many :fluxes, Magnify.Magnets.Flux, join_through: "magnets_fluxes"

    timestamps()
  end

[idi527]

Passing :user_id or any other foreign key into a changeset cast is an invitation for breaking into the system …

[Almog]

Ok so than what is the correct way to do it?

[idi527]

tl;dr

Just don’t put it into the params / changeset. Treat the params as an opaque data structure.

# in your controller

def create(conn, %{"magnet" => magnet_params}) do
    case Magnets.create_magnet(magnet_params, for: conn.assigns.current_user) do
      {:ok, magnet} ->
        conn
        |> put_flash(:info, "Magnet created successfully.")
        |> redirect(to: magnet_path(conn, :show, magnet))
      {:error, %Ecto.Changeset{} = changeset} ->
        render(conn, "new.html", changeset: changeset)
    end
end

# in your business logic module

def create_magnet(attrs, for: %User{id: user_id}) do
  %Magnet{user_id: user_id}
  |> Magnet.changeset(attrs)
  |> Repo.insert()
end

# in the module where you schema / changesets are defined
def changeset(manget, attrs) do
  magnet
  |> cast(attrs, [:title, :description, :content])
  |> validate_required([:title, :description, :content])
end

casting foreign keys in ecto changesets

Inserting model with association using create functions

menu = Cms.Content.create_menu(%{name: "Test Menu"}) What’s returned from Cms.Content.create_menu/1? Is it {:ok, menu}? I would probably avoid casting foreign keys in changesets (can open you up for vulnerabilities if attrs come from user input), but pass them to the create function “manually”. @spec create_menu_item(map, for: %Menu{}) :: {:ok, %MenuItem{}} | {:error, Ecto.Changeset.t()} def create_menu_item(attrs, for: %Menu{id: menu_id}) do %MenuItem{menu_id: menu_id} |> MenuItem.chang…

Phoenix : can't insert foreign keys in Postgres

Is there any reason that phoenix does not add these fields by default in validation ? Casting foreign keys from outside data can open you up for some nasty vulnerabilities. I saw a project that casted something like shop_id in their changesets and I could do whatever I wanted with them since I was practically “the owner” of every shop in their database. The fact that it’s so easy to do in ecto + phoenix is a bit worrisome.

What to do when you have to add a new parameter based on the result you get from a Service?

Hello folks! I have a question about how to deal with Context, in particular I see that from the perspective of controller tests all the keys of the params are passed as strings, while from the perspective of context|model tests we pass all the params keys as atoms. That’s not make a big difference cause what matter is that all the keys of a map have to be of the same type, but … I need to use a Service inside one of my Context so that based on the result I get from it I need to add a new key…

[dokuzbir]

I guessed so but i saw that example at thechangelog project so that made me think this is right too. Thanks for help

[Almog]

I tried doing that, i.e. having in the schema did " |> cast_assoc(:user)"

but it’s null, did you see my first post

[idi527]

guessed so but i saw that example at thechangelog project so that made me think this is right too.

You might want to warn them about it. As I’ve mentioned before, this approach (casting foreign keys inside the changeset functions) allowed me to gain write access to any record in one shop’s database once.