Cleanly add custom errors for Ecto.Changeset.cast/4

My initial thought was to do this in translate_errors using the error metadata, but I like this better since it keeps the error messages all in one place and not spread out…

Ecto types can already return custom error messages. For cast customizing the error doesn‘t really make sense as you‘d never really use it for individual fields.

That doesn’t work in our case. We have a union type that contains multiple embeds_one which delegates the specific validation logic for each type.

defmodule UnionStruct do
  use Ecto.Schema
  embedded_schema do
    embeds_one :url, UnionStruct.Url
    embeds_one :ssn, UnionStruct.Ssn
    embeds_one :phone_numer, UnionStruct.PhoneNumer
    embeds_one :date, UnionStruct.Date
    embeds_one :float, UnionStruct.Float
    embeds_one :Integer, UnionStruct.Integer

    field :other_data, :any
  end
end

# Example definition for PhoneNumber
defmodule UnionStruct.PhoneNumber do
  use Ecto.Schema

  embedded_schema do
    field :other_data, :any
    field :value, :string
  end

  def changeset(changeset, params, opts) do
    Ecto.Changeset.cast(changeset, params, [:value], opts)
    |> App.Changeset.custom_cast_error_message(:value, "Our custom phone number error message here")
    |> validate_phone_number(:value)
  end
end

For the fields like [:url, :phone_number, :ssn] those are all :string Ecto types. Hence why we can not have a single custom error message for :string when casting a value to :url, as the message we want to present with the input :url or :phone_number is different.

defmodule PhoneNumberType do
  use Ecto.Type

  def type, do: :string

  def cast(value) do
    case Ecto.Type.cast(:string, value) do
      {:ok, value} -> {:ok, value}
      :error -> {:error, "Our custom phone number error message here"}
    end
  end

  def dump(value), do: Ecto.Type.dump(:string, value)
  
  def load(value), do: Ecto.Type.load(:string, value)
end

defmodule UnionStruct.PhoneNumber do
  use Ecto.Schema

  embedded_schema do
    field :other_data, :any
    field :value, PhoneNumberType
  end

  def changeset(changeset, params, opts) do
    Ecto.Changeset.cast(changeset, params, [:value], opts)
    |> validate_phone_number(:value)
  end
end

You can wrap generic types like this to get more specific types. If you have many similar ones you can even abstract this using Ecto.ParameterizedType.

This was my first thought at addressing this issue, we have several custom Ecto types that such as our own date format that we can do this for. But our total number of types we would need to do this for is around 12. Maintaining those custom 12 types just to set a cast message didn’t feel like a good trade off for the long run.

defmodule CustomString do
  use Ecto.ParameterizedType

  def init(opts) do
    %{error: opts[:validation_message]}
  end

  def type(_), do: :string

  def cast(value, params) do
    case Ecto.Type.cast(:string, value) do
      {:ok, value} -> {:ok, value}
      :error -> {:error, params.error}
    end
  end

  def dump(value, _, _), do: Ecto.Type.dump(:string, value)
  def load(value, _, _), do: Ecto.Type.load(:string, value)
end

defmodule UnionStruct.PhoneNumber do
  use Ecto.Schema

  embedded_schema do
    field :value, CustomString, validation_message: "abc"
  end

  def changeset(changeset, params, opts) do
    Ecto.Changeset.cast(changeset, params, [:value], opts)
    |> validate_phone_number(:value)
  end
end