I have not set up any policies or looked at those, if that or something entirely different is the conventional way of scoping a query to a specific user, I can go down that road too.

The general pattern is to first ask yourself what kind of action you are writing. If you are writing the sort of action that is “contextual to the actor”, i.e. “create_my_thing”. vs “create_thing_for_user”. They are subtly different, and in many cases you may have both. I.e some admin version of an action that allows supplying any user.

Generally speaking, your best bet is to start by preferring to use the actor, and if later you determine that you want someone to be able to take that action “on behalf of” another user, you can either add another version of the action, or modify the internals of the action to expect an actor or a supplied user_id (for example).

All code interface functions accept an actor option, i.e YourResource.create!(...., actor: actor).

So to sum up, prefer to write “actor-specific” actions (as you described), as they are easier to reason about.

That is exactly what I needed Thank you, Zack.

Now that I know what I’m trying to do, I still can’t figure out how. There is only one example in the documentation, and it does not how how to make use of the built-in options.

Here is the resource:

defmodule Red.Practice.Card do
  use Ash.Resource,
    data_layer: AshPostgres.DataLayer

  actions do
    defaults [:create, :read, :update]
  end

  code_interface do
    define_for Red.Practice

    define :create, action: :create
  end

  attributes do
    integer_primary_key :id

    attribute :word, :string, allow_nil?: false
    attribute :tried_at, :utc_datetime, allow_nil?: true
    attribute :retry_at, :utc_datetime, allow_nil?: true
    attribute :correct_streak, :integer, allow_nil?: false, default: 0

    create_timestamp :created_at
    create_timestamp :updated_at
  end

  identities do
    identity :unique_word, [:word, :user_id]
  end

  relationships do
    belongs_to :user, Red.Accounts.User,
      attribute_writable?: true,
      attribute_type: :integer,
      allow_nil?: false
  end

  postgres do
    table "cards"
    repo Red.Repo
  end
end

What I was able to make work

Red.Practice.Card.create!(%{
  word: "other",
  user_id: user.id
})

It’s not what I want because I had to make the belongs_to attribute_writeable?: true which I don’t need at this point (not yet assigning cards to someone else).

But it fails when

I try to remove the attribute_writable?: true and pass the actor option,

Red.Practice.Card.create!(%{
  word: "the"
}, actor: user)

Here is the error:

** (Ash.Error.Invalid) Input Invalid

* attribute user_id is required
    (ash 2.15.17) lib/ash/api/api.ex:2183: Ash.Api.unwrap_or_raise!/3
    /Users/dewet/code/ash/red/README.livemd#cell:x6riuxlbaf4k7urdmoqee6tneokxl3mt:20: (file)

How do I fix this?

right, so now what you need to do is use the current user in the action to map it to the user relationship in some way.

The long way:

change fn changeset, context -> 
  Ash.Changeset.change_attribute(changeset, :user_id, context.actor.id)
end

The built in way:

# relate the actor to the `:user` relationship of this record.
change relate_actor(:user)

Badabing Badaboom

This worked:

  changes do
    change relate_actor(:user)
  end

I was able to remove the attribute_writable?: true from the relationship.

And now this works:

Red.Practice.Card.create!(%{
  word: "the"
}, actor: user)

Ah, you likely want this to be only in a specific action, i.e

create :create do
  change relate_actor(:user)
end

If it is in global changes, it will happen on all create and update actions.

Oh gotcha! Thanks for clarifying. I did that and it works.

Here’s my whole Resource now, just in case someone else is wanting a complete example:

defmodule Red.Practice.Card do
  use Ash.Resource,
    data_layer: AshPostgres.DataLayer

  actions do
    defaults [:read, :update]

    create :create do
      change relate_actor(:user)
    end
  end

  code_interface do
    define_for Red.Practice

    define :create, action: :create
  end

  attributes do
    integer_primary_key :id

    attribute :word, :string, allow_nil?: false
    attribute :tried_at, :utc_datetime, allow_nil?: true
    attribute :retry_at, :utc_datetime, allow_nil?: true
    attribute :correct_streak, :integer, allow_nil?: false, default: 0

    create_timestamp :created_at
    create_timestamp :updated_at
  end

  identities do
    identity :unique_word, [:word, :user_id]
  end

  relationships do
    belongs_to :user, Red.Accounts.User,
      attribute_writable?: true,
      attribute_type: :integer,
      allow_nil?: false
  end

  postgres do
    table "cards"
    repo Red.Repo
  end
end

I can’t guarantee that this file will keep living here, but if someone wants to see the up-to-date changes: red/lib/red/practice/resources/card.ex at main · dewetblomerus/red · GitHub