Controller Test with Pow

Questions / Help
1

I’ve added Pow into my project for authentication. Now I’m trying to update the tests Phoenix generated when I created my contexts.

I’ve added all my resource routes to the protected pipeline.

I used Pow.Plug.assign_current_user/3 to add a current user to my conn.

    test "redirects to show when data is valid", %{conn: conn} do
      user = %Golf.Accounts.User{email: "test@example.com", id: 1}
      conn = Pow.Plug.assign_current_user(conn, user, [])

      conn = post(conn, Routes.course_path(conn, :create), course: @create_attrs)

      assert %{id: id} = redirected_params(conn)
      assert redirected_to(conn) == Routes.course_path(conn, :show, id)

      conn = get(conn, Routes.course_path(conn, :show, id))
      assert html_response(conn, 200) =~ "Show Course"
    end

My assertions about the create action all pass.

      assert %{id: id} = redirected_params(conn)
      assert redirected_to(conn) == Routes.course_path(conn, :show, id)

However, the final show action

      conn = get(conn, Routes.course_path(conn, :show, id))
      assert html_response(conn, 200) =~ "Show Course"

fails because it gets redirected to the new_session path:

     ** (RuntimeError) expected response with status 200, got: 302, with body:
     <html><body>You are being <a href="/session/new?request_path=%2Fcourses">redirected</a>.</body></html>

If I reuse the original conn after I assign the current user, but before the create action, my tests pass.

    test "redirects to show when data is valid", %{conn: conn} do
      user = %Golf.Accounts.User{email: "test@example.com", id: 1}
      new_conn = Pow.Plug.assign_current_user(conn, user, [])

      conn = post(new_conn, Routes.course_path(new_conn, :create), course: @create_attrs)

      assert %{id: id} = redirected_params(conn)
      assert redirected_to(conn) == Routes.course_path(conn, :show, id)

      conn = get(new_conn, Routes.course_path(new_conn, :show, id))
      assert html_response(conn, 200) =~ "Show Course"
    end

Can someone help me out with how I need to update my tests?

Thanks!

Axel

2 Likes
2

Your second example is the way to go. This could also be done in a setup macro like so:

    setup %{conn: conn} do
      user = %Golf.Accounts.User{email: "test@example.com", id: 1}
      authed_conn = Pow.Plug.assign_current_user(conn, user, [])

      {:ok, conn: conn, authed_conn: authed_conn}
    end

    test "redirects to show when data is valid", %{authed_conn: authed_conn} do
      conn = post(authed_conn, Routes.course_path(authed_conn, :create), course: @create_attrs)

      assert %{id: id} = redirected_params(conn)
      assert redirected_to(conn) == Routes.course_path(conn, :show, id)

      conn = get(authed_conn, Routes.course_path(authed_conn, :show, id))
      assert html_response(conn, 200) =~ "Show Course"
    end

It’s because of how phoenix recycles connections in tests. The response conn will have a :state key set to :sent so when it’s reused the test helpers in Phoenix will build a new connection and only copy over headers e.g. cookies. Assigns will not be preserved.

7 Likes
3

If I am reading this thread right, there’s no point to have a test that does a POST and validates that Pow successfully authenticates a user then?

4

Yeah, you would only ever need to do that if you are testing the session controller itself. Assigning :current_user is sufficient for all other controllers/routes.

1 Like
5

Hi, After adding Pow, I has 9 test failing, after placing the setup macro to add the user to the conn i has 3 tests that keep failing with error.

** (RuntimeError) expected response with status 200, got: 302, with body:
“You are being <a href="/session/new?request_path=%2Fadmin%2Fproducts%2F150">redirected.”

If i remove :protected from pipeline on the scope all test pass. So it has to be something with the authentication. Thanks

6

Fixed. Had to recycle the conn manually.

test "redirects to show when data is valid", %{authed_conn: conn} do
      conn = post(conn, Routes.product_path(conn, :create), product: @create_attrs)
      assert %{id: id} = redirected_params(conn)
      assert redirected_to(conn) == Routes.product_path(conn, :show, id)

      conn = recycle_conn(conn) <-- Added

      conn = get(conn, Routes.product_path(conn, :show, id))
      assert html_response(conn, 200) =~ "Show Product"
    end

defp recycle_conn(conn) do
    saved_assigns = conn.assigns
    conn =
      conn
      |> recycle()
      |> Map.put(:assigns, saved_assigns)
    conn
  end

All the tests are passing now, but i have defined the recycle_conn function on the controller_test, what if i want to test another authed controller? Need to redefine again, or create another helper module and define it there to ease reuse.
Im pretty new to elixir/phoenix and web dev in general. Sorry for my english

1 Like