Creating a BEP3 compatible percent encoder (URI encoder)

This is not true, as trying it will demonstrate:

iex(1)> s = <<0xA8, 0x59, 0x72>>
<<168, 89, 114>>

iex(2)> URI.encode(s)
"%A8Yr"

I stand corrected; you’re right. URI.encode/1 will return letters in both uppercase and lowercase.

I set up some unit tests to make sure my encode function gives the same output as what qBittorrent does.

  # test/bep_encode_test.exs

  test "tails-amd64-6.10-img 07 b4 51 63 36 e4 af e9 23 2c 73 bc 31 26 42 59 0a 7d 7e 95" do
    actual = BepEncode.bep_encode("07b4516336e4afe9232c73bc312642590a7d7e95")
    expected = "%07%b4Qc6%e4%af%e9%23%2cs%bc1%26BY%0a%7d~%95"
    assert actual === expected
  end

  test "linuxmint-22-mate-64bit.iso e0 a4 05 8e 40 7d dd ad 1c ac f8 c9 ce db 0b 27 21 c0 7f 92" do
    actual = BepEncode.bep_encode("e0a4058e407dddad1cacf8c9cedb0b2721c07f92")
    expected = "%e0%a4%05%8e%40%7d%dd%ad%1c%ac%f8%c9%ce%db%0b%27!%c0%7f%92"
    assert actual === expected
  end

  test "debian-12.8.0-amd64-DVD-1.iso 56 3e 72 81 c0 00 e1 80 91 e5 c0 d3 9d 09 8c ff 13 5d ab 26" do
    actual = BepEncode.bep_encode("563e7281c000e18091e5c0d39d098cff135dab26")
    expected = "V%3er%81%c0%00%e1%80%91%e5%c0%d3%9d%09%8c%ff%13%5d%ab%26"
    assert actual === expected
  end

Looks like exclamation marks are allowed in BEP3 percent encoding. Custom URI.encode/2 predicate it is! I like how flexible it is because of that predicate arg.

  # lib/bep_encode.ex

  def char_allowed?(character) do
    character in ?0..?9 or character in ?a..?z or character in ?A..?Z or character in ~c"~_-.!"
  end


  @spec bep_encode(binary()) :: binary()
  def bep_encode(string) when is_binary(string) do
    string = Base.decode16!(string, case: :lower)
    URI.encode(string, &char_allowed?/1)
  end

Running tests, it looks like we’re almost there. Length is good, allowable special characters are left alone, but still there’s an issue of case in some of the hex values.

  3) test linuxmint-22-mate-64bit.iso e0 a4 05 8e 40 7d dd ad 1c ac f8 c9 ce db 0b 27 21 c0 7f 92 (BepEncodeTest)
     test/bep_encode_test.exs:19
     Assertion with === failed
     code:  assert actual === expected
     left:  "%E0%A4%05%8E%40%7D%DD%AD%1C%AC%F8%C9%CE%DB%0B%27!%C0%7F%92"
     right: "%e0%a4%05%8e%40%7d%dd%ad%1c%ac%f8%c9%ce%db%0b%27!%c0%7f%92"
     stacktrace:
       test/bep_encode_test.exs:22: (test)



  4) test tails-amd64-6.10-img 07 b4 51 63 36 e4 af e9 23 2c 73 bc 31 26 42 59 0a 7d 7e 95 (BepEncodeTest)
     test/bep_encode_test.exs:13
     Assertion with === failed
     code:  assert actual === expected
     left:  "%07%B4Qc6%E4%AF%E9%23%2Cs%BC1%26BY%0A%7D~%95"
     right: "%07%b4Qc6%e4%af%e9%23%2cs%bc1%26BY%0a%7d~%95"
     stacktrace:
       test/bep_encode_test.exs:16: (test)



  5) test debian-12.8.0-amd64-DVD-1.iso 56 3e 72 81 c0 00 e1 80 91 e5 c0 d3 9d 09 8c ff 13 5d ab 26 (BepEncodeTest)
     test/bep_encode_test.exs:25
     Assertion with === failed
     code:  assert actual === expected
     left:  "V%3Er%81%C0%00%E1%80%91%E5%C0%D3%9D%09%8C%FF%13%5D%AB%26"
     right: "V%3er%81%c0%00%e1%80%91%e5%c0%d3%9d%09%8c%ff%13%5d%ab%26"
     stacktrace:
       test/bep_encode_test.exs:28: (test)

Not sure why this is happening, but I’ll keep plugging along.

Eureka!

defmodule App.BittorrentUrlEncoder do
  @moduledoc """
  URL encoding for Bittorrent Info hash v1. Designed to be compatible with qBittorrent's percent encoding.
  """

  import Bitwise

  @doc """
  Encodes `string` as a Bittorrent-flavored percent-encoded string.

  ## Example

      iex> encode("a88fda5954e89178c372716a6a78b8180ed4dad3")
      "%a8%8f%daYT%e8%91x%c3rqjjx%b8%18%0e%d4%da%d3"

  """
  @spec encode(binary()) :: binary()
  def encode(hex_string) when is_binary(hex_string) do
    hex_string
    |> Base.decode16!(case: :lower) # Decode from hex to raw bytes
    |> encode_bytes()
  end

  defp encode_bytes(<<>>), do: ""

  defp encode_bytes(<<byte, rest::binary>>) do
    percent_encode(byte) <> encode_bytes(rest)
  end

  defp percent_encode(byte) when byte in ?0..?9 or byte in ?a..?z or byte in ?A..?Z or byte in ~c"~_-.!" do
    <<byte>>
  end

  defp percent_encode(byte) do
    "%" <> <<hex(bsr(byte, 4)), hex(band(byte, 15))>>
  end

  defp hex(n) when n <= 9, do: n + ?0
  defp hex(n), do: n + ?a - 10
end

The secret sauce was changing ?A to ?a in the hex/1 function

-defp hex(n), do: n + ?A - 10
+defp hex(n), do: n + ?a - 10