The AST from that issue pretty-prints to:

[arg0 = case(slot(:greet) do
  {:safe, ["    <strong>Hello!<strong>\n"]}
end) do
  {:safe, data} ->
    data
  bin when is_binary(bin) ->
    Plug.HTML.html_escape_to_iodata(bin)
  other ->
    Phoenix.HTML.Safe.to_iodata(other)
end, arg1 = case(slot(:name) do
  {:safe, ["    <span>John</span>\n"]}
end) do
  {:safe, data} ->
    data
  bin when is_binary(bin) ->
    Plug.HTML.html_escape_to_iodata(bin)
  other ->
    Phoenix.HTML.Safe.to_iodata(other)
end, {:safe, [arg0, arg1, "  <p>How are you?</p>\n"]}]

or distilled to its essence:

[a = 1, b = 2, a + b]

This fragment doesn’t compile either:

** (CompileError) iex:5: undefined function a/0
    (stdlib 3.13.2) lists.erl:1358: :lists.mapfoldl/3

The issue is that a list of AST nodes is not the same as a block.

This version of the simplified example does compile (and returns 3):

(a = 1; b = 2; a + b)

(or you can use newlines instead of ;)

The difference is clear in their respective ASTs:

iex(9)> quote do: [a = 1, b = 2, a + b] 
[
  {:=, [], [{:a, [], Elixir}, 1]},
  {:=, [], [{:b, [], Elixir}, 2]},
  {:+, [context: Elixir, import: Kernel], [{:a, [], Elixir}, {:b, [], Elixir}]}
]

iex(10)> quote do: (a = 1; b = 2; a + b)
{:__block__, [],
 [
   {:=, [], [{:a, [], Elixir}, 1]},
   {:=, [], [{:b, [], Elixir}, 2]},
   {:+, [context: Elixir, import: Kernel], [{:a, [], Elixir}, {:b, [], Elixir}]}
 ]}