Custom action using manage_relationship when relationship is many_to_many

Resources involved are Employee, Shift, and EmployeeShift

Employee and shift are related many_to_many, through EmployeeShift, however, since an employee can clock in and out multiple times during an shift EmployeeShift has it’s own id and isn’t unique by pairs of Employee and Shift ids:

  attributes do
    uuid_primary_key :id
    attribute :in_at, :utc_datetime_usec, allow_nil?: false
    attribute :out_at, :utc_datetime_usec

    create_timestamp :created_at
    update_timestamp :updated_at
  end

  relationships do
    belongs_to :employee, PointOfSale.Accounts.Employee do
      api PointOfSale.Accounts
      allow_nil? false
      attribute_writable? true
    end

    belongs_to :shift, PointOfSale.Stores.Shift do
      allow_nil? false
      attribute_writable? true
    end
  end

Additionally EmployeeShifts have a custom primary create action called start that takes arguments of employ_id and shift_id and set’s the start time:

create :start do
      primary? true
      accept [:employee_id, :shift_id]

      argument :employee_id, :uuid, allow_nil?: false
      argument :shift_id, :uuid, allow_nil?: false

      change set_attribute(:in_at, DateTime.utc_now())
      change set_attribute(:employee_id, arg(:employee_id))
      change set_attribute(:shift_id, arg(:shift_id))
    end

When I start a new Shift I want to be able to pass an array of Employee ids to manage_relationship so that the custom start create function is called on EmployeeShift so that the included employees are clocked in automatically as the shift starts:

Shift


    has_many :employee_shifts, PointOfSale.Stores.EmployeeShift

    many_to_many :employees, PointOfSale.Accounts.Employee do
      api PointOfSale.Accounts
      through PointOfSale.Stores.EmployeeShift
      join_relationship :employee_shifts
    end
create :start do
      accept [:till_id, :employee_ids]

      argument :till_id, :uuid, allow_nil?: false
      argument :employee_ids, {:array, :uuid}, allow_nil?: false

      change set_attribute(:start_at, DateTime.utc_now())
      change set_attribute(:till_id, arg(:till_id))
      change manage_relationship(:employee_ids, :employee_shifts, type: create)
    end

However, when I attempt to create a new Shift via this action I get an error saying that the required arguments of shift_id and employee_id for EmployeeShift are missing.

The shift_id should come from the shift that is created just before running the manage relationship. And I thought I would be accepting employee_ids via the manage_relationship function.

I see that I can pass a map instead of a list of ids, and maybe that is the way, but that doesn’t solve the passing in of the shift_id that I don’t have since it get’s created.

Hmm…this rings a bell on a bug that was fixed in the not too distant past. How up to date is your ash version?

OK, updated everything, still no luck:

iex(4)> shift = Shift.start!(%{till_id: till.id, employee_ids: employee_ids}, tenant: "dreambean")
[debug] QUERY OK db=0.2ms idle=1367.8ms
begin []
↳ anonymous fn/3 in Ash.Changeset.with_hooks/3, at: lib/ash/changeset/changeset.ex:2186
[debug] QUERY OK source="shifts" db=3.5ms
INSERT INTO "dreambean"."shifts" ("id","created_at","updated_at","start_at","till_id") VALUES ($1,$2,$3,$4,$5) RETURNING "till_id","updated_at","created_at","end_at","start_at","id" ["e3758301-5c59-4b8b-8fbc-ae80f258b281", ~U[2024-02-08 16:44:03.213427Z], ~U[2024-02-08 16:44:03.213427Z], ~U[2024-02-08 16:29:33Z], "9f5d6205-70f0-43ca-8a74-dc5de13b7886"]
↳ AshPostgres.DataLayer.bulk_create/3, at: lib/data_layer.ex:1412
[debug] QUERY OK db=0.4ms
rollback []
↳ anonymous fn/3 in Ash.Changeset.with_hooks/3, at: lib/ash/changeset/changeset.ex:2186
** (Ash.Error.Invalid) Input Invalid

* argument employee_id is required    at employee_ids, 0

* argument shift_id is required    at employee_ids, 0

    (ash 2.18.2) lib/ash/api/api.ex:2711: Ash.Api.unwrap_or_raise!/3
    iex:4: (file)

ah, okay interesting. Sorry, didn’t notice this until now.

Try this:

      change manage_relationship(:employee_ids, :employee_shifts, type: :create, value_is_key: :employee_id)
1 Like

That solves the employee_id :tada:

But not the shift_id

** (Ash.Error.Invalid) Input Invalid

* argument shift_id is required    at employee_ids, 0

    (ash 2.18.2) lib/ash/api/api.ex:2711: Ash.Api.unwrap_or_raise!/3
    iex:4: (file)
1 Like

I’m wondering if I even need the many_to_many at this point because the join table now has its own attributes and id, so should it really be modeled that way? I’m going to see if it changes anything. I don’t expect it to since the function is operating on the has_many relationship.

Yeah, that didn’t change it. I wonder if it is because EmployeeShift doesn’t use shift_id or employee_id as primary keys.

Same result.

Ah, okay I think its because its using the primary create action on the join resource which you’ve configured with required arguments.

You’ll need to point it at a different create action and/or make those arguments optional (because manage_relationship writes to the attributes, it doesn’t set arguments).

Ah, I see, lemme throw in new action in there. Does it always use the primary action or is there a way to specify?

For the benefit of future generations here is the new action used by Shift.start/ to create EmployeeShifts from an array of employee_ids just after the Shift is created:

  create :start_from_shift do
      primary? true
      accept [:employee_id]

      argument :employee_id, :uuid, allow_nil?: false

      change set_attribute(:employee_id, arg(:employee_id))
      change set_attribute(:in_at, DateTime.utc_now())
    end

This is the action that calls it:

  create :start do
      primary? true
      accept [:till_id, :employee_ids]

      argument :till_id, :uuid, allow_nil?: false
      argument :employee_ids, {:array, :uuid}, allow_nil?: false

      change set_attribute(:start_at, DateTime.utc_now())
      change set_attribute(:till_id, arg(:till_id))

      change manage_relationship(:employee_ids, :employee_shifts,
               type: :create,
               value_is_key: :employee_id
             )
    end

Looks like maybe doesn’t support specifying the action to use, but just uses the primary:

 change manage_relationship(:employee_ids, :employee_shifts,
               type: :create,
               action: :start_from_shift,
               value_is_key: :employee_id
             )

** (NimbleOptions.ValidationError) unknown options [:action], valid options are: [:type, :authorize?, :eager_validate_with, :on_no_match, :value_is_key, :identity_priority, :use_identities, :on_lookup, :on_match, :on_missing, :error_path, :meta, :ignore?]

The action is specified by modifying the underlying keys for manage_relationship.

type: :create maps to

[
  on_no_match: :create,
  on_match: :ignore
]

The docs for it are here: Ash.Changeset — ash v2.18.2

So you’d say:

type: :create,
on_match: {:create, :action_name, :join_table_action_name, []}
2 Likes

Perfect, thank you :pray: :partying_face:

I think this should be on_no_match, correct?

So the action on EmployeeShift is no longer primary so it looks like this:

 create :start_from_shift do
      accept [:employee_id]

      argument :employee_id, :uuid, allow_nil?: false

      change set_attribute(:employee_id, arg(:employee_id))
      change set_attribute(:in_at, DateTime.utc_now())
    end

And the manage_relationship action in Shift now looks like this, with the updated specification for when we go to create, there is no match (which should always be true), I specify that I want to use the :create action called :start_from_shift.

Since I’m doing this through the has_many and not the many_to_many, I’m not specifying a join table action name, just the action name and since I’m providing a list of UUIDs I specify that those values are for using as the employee_id parameter that the :start_from_shift action requires.

 change manage_relationship(:employee_ids, :employee_shifts,
               type: :create,
               on_no_match: {:create, :start_from_shift},
               value_is_key: :employee_id
             )
1 Like

Ah, yeah typo on my part :+1: