Dbg() in a `with` sequence?

dogweather

dbg() is one of my favorite Elixir features: placing it somewhere in a pipe of function calls outputs all the intermediate results. It’s great for debugging parsing code. Like this:

    meta_date =
      document
      |> Floki.find("meta[property='article:published_time']")
      |> Floki.attribute("content")
      |> List.first()
      |> parse_date_text()
      |> dbg()

Well, now I’m starting to use with instead of |>. Is it possible to get that dbg() behavior? I haven’t figured it out. For example:

  @spec parse_human_date_string(binary) :: nil | Date.t
  def parse_human_date_string(text) when is_binary(text) do
    with [_, raw_month, raw_day, year] <- Regex.run(~r/^(.+) (.+), (\d\d\d\d)$/, text),
          day        <- String.pad_leading(raw_day, 2, "0"),
          month_num  <- Integer.to_string(Enum.find_index(@months, &(&1 == raw_month)) + 1),
          month      <- String.pad_leading(month_num, 2, "0"),
         {:ok, date} <- Date.from_iso8601("#{year}-#{month}-#{day}"),
         dbg() do  ### THIS IS WHAT I'D LIKE TO DO ###
      date
    else
      _ -> nil
    end
  end

Then I’d get the results of each “line” of the with.

6 comments

#debugging #with

0 1602 6

2023-12-27 00:37:18 UTC

Showing Posts 1 to 6

Show Best Posts
Show All (oldest first)
Show All (newest first)

dogweather

Never mind—it freakin’ works. Amazing.

Post #1

sodapopcan

Wait, what did you do!? Simply placing a dbg() as its own clause didn’t work for me. Is it exactly as in your example?

Post #2

dogweather

Yep, just make dbg() one of the clauses. I’ll paste here the actual running code and the output. I’m pretty sure it’s the same as above:

  @spec parse_human_date_string(binary) :: Date.t | nil
  def parse_human_date_string(text) when is_binary(text) do
    with [_, raw_month, raw_day, year] <- Regex.run(~r/^(.+) (.+), (\d\d\d\d)$/, text),
          day        <- String.pad_leading(raw_day, 2, "0"),
          month_num  <- Integer.to_string(Enum.find_index(@months, &(&1 == raw_month)) + 1),
          month      <- String.pad_leading(month_num, 2, "0"),
         {:ok, date} <- Date.from_iso8601("#{year}-#{month}-#{day}"),
         dbg() do
      date
    else
      _ -> nil
    end
  end

~/s/P/oregon-revised-statutes-crawler ❯❯❯ mix test                                                       refactor ✱
Compiling 1 file (.ex)
Generated crawlers app
................................................................................................................................[lib/news/date_modified.ex:99: News.DateModified.parse_human_date_string/1]
binding() #=> [
  date: ~D[2023-12-05],
  day: "05",
  month: "12",
  month_num: "12",
  raw_day: "5",
  raw_month: "December",
  text: "December 5, 2023",
  year: "2023"
]

..........[lib/news/date_modified.ex:99: News.DateModified.parse_human_date_string/1]
binding() #=> [
  date: ~D[1997-05-26],
  day: "26",
  month: "05",
  month_num: "5",
  raw_day: "26",
  raw_month: "May",
  text: "May 26, 1997",
  year: "1997"
]

..[lib/news/date_modified.ex:99: News.DateModified.parse_human_date_string/1]
binding() #=> [
  date: ~D[2020-01-01],
  day: "01",
  month: "01",
  month_num: "1",
  raw_day: "1",
  raw_month: "January",
  text: "January 1, 2020",
  year: "2020"
]

.......
Finished in 0.9 seconds (0.4s async, 0.5s sync)
17 doctests, 130 tests, 0 failures

Post #3

dogweather

BTW, @josevalim this is mind-blowingly good.

Post #4

sodapopcan

OIC, dbg() without explicit args (or pipe) just outputs the current binding which I never realized before.

For example:

if true do
  a = 1
  dbg()
end
binding() #=> [a: 1]

Cool!

PS, I wasn’t able to get it to work before because I was being dumb and trying this: with 1 <- 1, 2 <- 2, dbg(), do: "hi" so of course I got binding() #=> []