"defstruct" diffrenet behaviors in iex and elixir

You have your lines of:

s1 = %Subscriber{}
IO.puts inspect(s1)

Outside of a function, you should put them in a function.

You can also run it in iex directly as well:

iex1> defmodule Subscriber do
...1>   defstruct name: "", paid: false, over_18: true
...1> end
{:module, Subscriber,
 <<70, 79, 82, 49, 0, 0, 5, 124, 66, 69, 65, 77, 65, 116, 85, 56, 0, 0, 0, 146,
   0, 0, 0, 13, 17, 69, 108, 105, 120, 105, 114, 46, 83, 117, 98, 115, 99, 114,
   105, 98, 101, 114, 8, 95, 95, 105, 110, ...>>,
 %Subscriber{name: "", over_18: true, paid: false}}
iex2> s1 = %Subscriber{}
%Subscriber{name: "", over_18: true, paid: false}
iex3> IO.puts inspect(s1)
%Subscriber{name: "", over_18: true, paid: false}
:ok

Everything in elixir should be in a module. Try this in your file.

defmodule Subscriber do
  defstruct name: "", paid: false, over_18: true
end

defmodule Run do
  s1 = %Subscriber{}
  IO.puts inspect(s1)
end

I do not think so!

Defining a struct and using it in the following script is essential in scripting with elixir.

Yes you are right indeed. My mistake. I don’t know why I had this impression.

Thanks for leading me. However, this issue comes out using “Elixir defstruct.exs” although using iex as you said works correctly.

In addition, I think “iex” and “elixir” packages are different in my environment. I might miss installing correctly. When I checked “mix deps.get”, errors happen and are still unresolved.

The issue is with the phases that the Elixir compiler goes through.

While this

defmodule Subscriber do
  defstruct name: "", paid: false, over_18: true

end
s1 = %Subscriber{}
IO.puts inspect(s1)

results in an error, the following does not

defmodule Subscriber do
  defstruct name: "", paid: false, over_18: true

  def new,
    do:  %Subscriber{}

end
s1 = Subscriber.new()
IO.puts inspect(s1) 

During compilation the expansion phase happens before the evaluation phase. However the functionality of a module isn’t “defined” and available until it has been evaluated during the evaluation phase. So when the compiler comes across

s1 = %Subscriber{}

during the expansion phase it tries to expand %Subscriber{} - the problem is that %Subscriber{} is part of the Subscriber module which won’t be defined until later in the evaluation phase - so during the expansion phase there is no definition for %Subscriber{} (yet).

s1 = Subscriber.new()

doesn’t have anything to expand - it is simply a function call that is evaluated during the evaluation phase - by that point in time the Subscriber module has been fully evaluated and both %Subscriber{} and Subscriber.new() are defined and available.

See also

Main phases of Elixir compilation

peerreynders, Thank you so much.
I corrected my codes as what you said and it works. And I learned a lot from you.

modified code:

defmodule Subscriber do  
  defstruct name: "", paid: false, over_18: true

  def run do
    s1 = %Subscriber{}
    IO.puts inspect(s1)
    s2 = %Subscriber{name: "Dave"}
    IO.puts inspect(s2)
    s3 = %Subscriber{ name: "Mary", paid: true}
    IO.puts inspect(s3)
    IO.puts "#{s3.name}"
    %Subscriber{name: a_name} = s3
    IO.puts a_name
    s4 = %Subscriber{ s3 | name: "Marie"}
    IO.puts inspect(s4)
  end 
end

Subscriber.run()