I now am at a computer, so it is easier to mock out a code example.

This is what I have done lately for a proof-of-concept ‘online game’, where game state is regularly updated, and then pushed towards all connected players. It does not depend on a database, since updating the data usually does not depend on the database (unless another application connects directly with the database, in which case Boltun might be what you want).

In the module that maintains the player state, I run the following function when this is updated:

  defp broadcast_update(state) do
    Phoenix.PubSub.broadcast(OnlineGame.PubSub, "player_state_update:#{state.user_id}", {:player_state_update, state})
  end

(Note that OnlineGame.PubSub is the name configured for Phoenix Pubsub, see your Phoenix config file, it will by default be MyAppName.PubSub.)

This will send an update to any other process that would like to listen to the player_state_update:2 topic.
To subscribe a Phoenix Channel to this, which forwards the information over a Phoenix Channel to a user’s Browser, I have the following

code in the channel:

defmodule OnlineGame.Web.GameChannel do
  use Phoenix.Channel

  def join("player_state_update", _params, socket) do
    user_id = get_user_id_in_some_way()
    Phoenix.PubSub.subscribe(OnlineGame.PubSub, "player_state_update:#{user_id}")
    # Some other stuff not relevant for this example, and finally:
    {:ok, socket}
  end

  def handle_info({:player_state_update, player_state}, socket) do
    push socket, "player_state_update", player_state
    {:noreply, socket}
  end
end

So you just override the handle_info from another GenServer. Note that, since the process just receives the message without being given information about what topic it was the message arrived on, it makes sense to send a tuple like this.
The implementation of handle_info here just forwards the information to the socket.

The cool thing about this approach, is that my Game context does not need to know that I use Phoenix. (But just that I use Phoenix.PubSub). I could register to this update in any other location of the application.