Help with writing Ecto.Multi function

Phoenix Forum Questions / Help
,
1

Hello,

I’m having a bit of trouble creating a function with EctoMulti. I have support_tickets which have many support_ticket_messages. When I want to insert new message, I have the following function which takes the attrs and puts association to ticket and user and this function works just fine.

def create_support_ticket_message(%SupportTicket{} = ticket, %User{} = user, attrs) do
    %SupportTicketMessage{seen: false}
    |> SupportTicketMessage.changeset(attrs)
    |> Ecto.Changeset.put_assoc(:support_ticket, ticket)
    |> Ecto.Changeset.put_assoc(:user, user)
    |> Repo.insert()
end

Now, I want to send notification to the user when new message is created so I wanted to use Ecto.Multi() but I’m not sure how to write it properly. The following function doesn’t work because I need to use a function to use Ecto.build_assoc() and I have only a changeset which contain message attrs.

changeset = SupportTicketMessage.changeset(attrs)

Multi.new()
    |> Multi.insert(:support_ticket_message, changeset ->
        Ecto.build_assoc(ticket, :support_ticket_messages)
        Ecto.build_assoc(user, :user)
      end)
    |> Repo.transaction()

How to write this function properly?

2

Just solved it this way but if someone knows a better way, I would be happy to hear it.

changeset =
      %SupportTicketMessage{user_id: user.id, ticket_id: ticket.id}
      |> SupportTicketMessage.changeset(attrs)

    Multi.new()
    |> Multi.insert(:support_ticket_message, changeset)
    |> Repo.transaction()
3

Looks like you got it but since I typed this all out I’m gonna post anyway :sweat_smile: I included the run function you can use if you want notifying the user to be part of the transaction.

def support_ticket_message_changeset(%SupportTicket{} = ticket, %User{} = user, attrs) do
  %SupportTicketMessage{seen: false}
  |> SupportTicketMessage.changeset(attrs)
  |> Ecto.Changeset.put_assoc(:support_ticket, ticket)
  |> Ecto.Changeset.put_assoc(:user, user)
end

Multi.new()
|> Multi.insert(:ticket, support_ticket_changeset(ticket, user, attrs))
|> Multi.run(:notification, fn _repo, %{ticket: ticket} ->
  notify_user_about_ticket(ticket, user)
end)
|> Repo.transaction()
4 Likes
4

It’s worth noting though that if there isn’t a good reason to fail the operation if the user isn’t notified (and I would think this is generally the case) you don’t need a Multi here as a changeset with associations is automatically run in a transaction with Repo.insert and friends.

2 Likes