chokchit
How can I compare two list of maps?
Hey guys, just want a little help.
(1) How can I compare two list of maps and always supersedes list_2 over list_1 if they have the same name? and (2) return the map of list_1 if it doesn’t have a similar name?
Given:
list_1 = [%{id: 1, name: "John"}, %{id: 1, name: "Jane"}, %{school_id: 1, name: "Ryan"}, ...]
list_2 = [%{id: 2, name: "John"}, %{id: 2, name: "Jane"}, ...]
Expected result:
[
%{school_id: 2, name: "John"},
%{school_id: 2, name: "Jane"},
%{school_id: 1, name: "Ryan"},
...
]
Most Liked
imatmati
Enum.concat(list_2,list_1)
|> Enum.sort( &(&1.name<= &2.name))
|> Enum.dedup_by(&(&1.name))
6
amnu3387
Two other ways are using Enum.reduce/3 or a reduction function:
Enum.concat(Test.list_2(), Test.list_1())
|> Enum.reduce({[], %{}}, fn
(%{name: name}, {_, map_matches} = full_acc) when :erlang.is_map_key(name, map_matches) ->
full_acc
(%{name: name} = el, {acc, map_matches}) ->
{[el | acc], Map.put(map_matches, name, true)}
end)
|> elem(0)
Or
def build(list, acc \\ {[], %{}})
def build([], {acc, _}), do: acc
def build([%{name: name} | t], {_acc, map_matches} = full_acc) when :erlang.is_map_key(name, map_matches), do: build(t, full_acc)
def build([%{name: name} = el | t], {acc, map_matches}) do
build(t, {[el | acc], Map.put(map_matches, name, true)})
end
#test.exs
defmodule Test do
@list_1 Enum.reduce_while(Stream.cycle([0]), {0, []},
fn(_n, {count, acc}) when count < 25000 ->
{:cont, {count + 1, [%{id: count + 1, name: "a_#{count}_name"} | acc]}}
(_, {_, acc}) -> {:halt, acc}
end)
@list_2 @list_1 |> List.delete_at(10) |> List.delete_at(50) |> List.delete_at(100) |> List.delete_at(500) |> List.delete_at(750)
def list_1, do: @list_1
def list_2, do: @list_2
# reduce w/ function
def build(list, acc \\ {[], %{}})
def build([], {acc, _}), do: acc
def build([%{name: name} | t], {_acc, map_matches} = full_acc) when :erlang.is_map_key(name, map_matches), do: build(t, full_acc)
def build([%{name: name} = el | t], {acc, map_matches}) do
build(t, {[el | acc], Map.put(map_matches, name, true)})
end
def test do
test1 =
Enum.concat(Test.list_2(), Test.list_1())
|> Enum.reduce({[], %{}}, fn
(%{name: name}, {_, map_matches} = full_acc) when :erlang.is_map_key(name, map_matches) -> full_acc
(%{name: name} = el, {acc, map_matches}) ->
{[el | acc], Map.put(map_matches, name, true)}
end)
|> elem(0)
|> Enum.sort()
test2 =
:lists.flatten([Test.list_2() | Test.list_1()])
|> Enum.reduce({[], %{}}, fn
(%{name: name}, {_, map_matches} = full_acc) when :erlang.is_map_key(name, map_matches)-> full_acc
(%{name: name} = el, {acc, map_matches}) ->
{[el | acc], Map.put(map_matches, name, true)}
end)
|> elem(0)
|> Enum.sort()
test3 =
Map.new(Test.list_1(), &{&1.name, &1})
|> Map.merge(Map.new(Test.list_2(), &{&1.name, &1}))
|> Enum.map(&elem(&1, 1))
|> Enum.sort()
test4 =
Enum.concat(Test.list_2(), Test.list_1())
|> Enum.sort( &(&1.name<= &2.name))
|> Enum.dedup_by(&(&1.name))
|> Enum.sort()
test5 =
Enum.map(Test.list_1(), fn %{name: n} = m ->
Enum.find(Test.list_2(), m, &match?(%{name: ^n}, &1))
end)
|> Enum.sort()
test6 =
Enum.concat(Test.list_2(), Test.list_1())
|> Test.build()
|> Enum.sort()
IO.inspect(test1 == test2, label: "1 == 2")
IO.inspect(test1 == test3, label: "1 == 3")
IO.inspect(test1 == test4, label: "1 == 4")
IO.inspect(test1 == test5, label: "1 == 5")
IO.inspect(test1 == test6, label: "1 == 6")
end
end
defmodule TestTest do
Test.test()
end
Benchee.run(
%{
"Enum.reduce & concat" => fn ->
Enum.concat(Test.list_2(), Test.list_1())
|> Enum.reduce({[], %{}}, fn
(%{name: name}, {_, map_matches} = full_acc) when :erlang.is_map_key(name, map_matches) -> full_acc
(%{name: name} = el, {acc, map_matches}) ->
{[el | acc], Map.put(map_matches, name, true)}
end)
|> elem(0)
end,
"Enum.reduce & flatten" => fn ->
:lists.flatten([Test.list_2() | Test.list_1()])
|> Enum.reduce({[], %{}}, fn
(%{name: name}, {_, map_matches} = full_acc) when :erlang.is_map_key(name, map_matches)-> full_acc
(%{name: name} = el, {acc, map_matches}) ->
{[el | acc], Map.put(map_matches, name, true)}
end)
|> elem(0)
end,
"reduce function" => fn ->
Enum.concat(Test.list_2(), Test.list_1())
|> Test.build()
end,
"map_merge" => fn ->
Map.new(Test.list_1(), &{&1.name, &1})
|> Map.merge(Map.new(Test.list_2(), &{&1.name, &1}))
|> Enum.map(&elem(&1, 1))
end,
"sort_dedup" => fn ->
Enum.concat(Test.list_2(), Test.list_1())
|> Enum.sort( &(&1.name<= &2.name))
|> Enum.dedup_by(&(&1.name))
end,
"enum_find" => fn ->
Enum.map(Test.list_1(), fn %{name: n} = m ->
Enum.find(Test.list_2(), m, &match?(%{name: ^n}, &1))
end)
end
},
time: 2
)
Which gives:
1 == 2: true
1 == 3: true
1 == 4: true
1 == 5: true
1 == 6: true
Operating System: macOS"
CPU Information: Intel(R) Core(TM) i7-4750HQ CPU @ 2.00GHz
Number of Available Cores: 8
Available memory: 8 GB
Elixir 1.7.2
Erlang 21.0
Benchmark suite executing with the following configuration:
warmup: 2 s
time: 2 s
memory time: 0 μs
parallel: 1
inputs: none specified
Estimated total run time: 24 s
Benchmarking Enum.reduce & concat...
Benchmarking Enum.reduce & flatten...
Benchmarking enum_find...
Benchmarking map_merge...
Benchmarking reduce function...
Benchmarking sort_dedup...
Name ips average deviation median 99th %
reduce function 53.90 18.55 ms ±9.14% 19.02 ms 23.64 ms
Enum.reduce & flatten 51.34 19.48 ms ±9.26% 19.40 ms 23.77 ms
Enum.reduce & concat 50.97 19.62 ms ±8.30% 20.04 ms 22.77 ms
map_merge 46.92 21.31 ms ±7.83% 21.44 ms 25.13 ms
sort_dedup 43.35 23.07 ms ±6.16% 23.07 ms 26.70 ms
enum_find 0.0740 13515.56 ms ±0.00% 13515.56 ms 13515.56 ms
Comparison:
reduce function 53.90
Enum.reduce & flatten 51.34 - 1.05x slower
Enum.reduce & concat 50.97 - 1.06x slower
map_merge 46.92 - 1.15x slower
sort_dedup 43.35 - 1.24x slower
enum_find 0.0740 - 728.52x slower
The results change depending on the length of the lists, but the function is always a tad faster
4
gregvaughn
Enum.map(list_1, fn %{name: n} = m ->
Enum.find(list_2, m, &match?(%{name: ^n}, &1))
end)
2
Popular in Questions
In Ruby, I can go:
User.find_by(email: "foobar@email.com").update(email: "hello@email.com")
How can I do something similar in Elixir?
...
New
I believe there are people here who are dealing with CSV files import on the daily basis, and since Excel is a really popular tool there ...
New
What is the idiomatic way of matching for not nil in Elixir?
E.g.,
First way:
defp halt_if_not_signed_in(conn, signed_in_account) when...
New
I have seen a lot of code which picks the first element from a list using Enum.at(0) instead of List.first. Is there a reason why people ...
New
Forgive me if this is obvious, but how does one delete a database record WITHOUT selecting it first? Ecto.Repo — Ecto v3.14.0 has exampl...
New
I am using Ecto timestamps with postgres, I can see the timestamps() use the :naive_dateime but for my use case I wanted to store the ti...
New
I have a User schema with a :from_id field set to type :string:
defmodule TweetBot.Repo.Migrations.CreateUsers do
use Ecto.Migration
...
New
There are pre-rolled solutions for other frameworks that do work. However, Phoenix does not seem to have these. Have people had good expe...
New
I want to highlight html closing tags when i click a html tag. That works in .html files but doesnt work for html.eex templates. How can...
New
In asking this question I am more interested about the expressiveness of the language itself and less concerned about the availability of...
New
Other popular topics
I have a another noob question about loop. Since elixir is immutable, while loop is not directly possible.
total = 10
while total != 0
...
New
Hello, can anybody help here..? I have a list of players and I what to delete an element, but every for loop the list is reverting to ori...
New
Posting this to see if we can make things easier for people to get into Neovim. If you use Neovim and have a favourite distro please let ...
New
I am trying to figure out how Mix knows whether the environment is test, dev, or prod – where is this set?
Thanks.
New
I have a relationship of love and hate with Elixir. Lots of things are just absolutely right, but there are some things that are kind of ...
New
About me? ( if you have nothing better to do than reading about some random guy in the internet :stuck_out_tongue: )
Hello all, this is ...
New
What learn first? Rust or Elixir
Hi Elixir community!
I’m here because i want learn a new language. I’m a junior developer and mainly i ...
New
Why is it that the mnesia database isn’t the most preferred database for use in Elixir/Phoenix?
New
For some reason my phoenix channels are working for me in my local dev environment, but as soon as I deploy via Docker, I get a 403 error...
New
In asking this question I am more interested about the expressiveness of the language itself and less concerned about the availability of...
New
Latest on Elixir Forum
Sponsor Spotlight
We build reliable cloud platforms for business-critical systems.
Categories:
Sub Categories:
Forums
Popular Tags
- #ecto
- #liveview
- #troubleshooting
- #learning-elixir
- #deployment
- #library
- #erlang
- #testing
- #genserver
- #mix
- #absinthe
- #remote-other
- #otp
- #plug
- #how-to-question
- #macros
- #postgres
- #channels
- #elixirconf
- #exunit
- #discussion
- #code-sync
- #javascript
- #podcasts
- #onsite
- #dialyzer
- #docker
- #authentication
- #umbrella
- #full-time-contract
- #podcasts-by-brainlid
- #ecto-query
- #elixir-ls
- #phoenix_html
- #iex
- #blog-post
- #graphql
- #genstage
- #ai
- #websockets
- #supervisor
- #advent-of-code
- #elixirconf-us
- #distillery
- #processes
- #forms
- #api
- #metaprogramming
- #security
- #performance
Our Sponsors
Build Elixir applications with speed and confidence.
Supporting innovation across the BEAM ecosystem.
We build reliable cloud platforms for business-critical systems.
Catch errors, track performance, monitor hosts and more.
Real-time error tracking, performance insights, and observability for devs.
Producing high quality Elixir screencasts since 2017.
Enabling companies to succeed by building software people love.
The deployment platform built for Elixir: PaaS ease, VPS control.
The team behind Membrane, Popcorn, LiveDebugger. Available for hire.
Courses that'll move you from confusion to "Aha, now I get it!"