how to create database on release

dinasol

how would I create database on release task with elixir 1.9?
I found on hexdocx Deploying with Releases — Phoenix v1.8.8 how to run migration, but not database creation

before I upgraded to 1.9 I had in my release script create and migrate following this: https://ronantreacy.com/blog/deploying-phoenix-applications-using-docker-and-distillery

here is my code for creating database:

defmodule Release.Tasks do

  @start_apps [ :postgrex, :ecto ]

  @myapps [:my_app]

  @repos [MyApp.Repo]

  def createdb do

    # Ensure all apps have started
    Enum.each(@myapps, fn(x) ->
      :ok = Application.load(x)
    end)

    # Start postgrex and ecto
    Enum.each(@start_apps, fn(x) ->
      {:ok, _} = Application.ensure_all_started(x)
    end)

    # Create the database if it doesn't exist
    Enum.each(@repos, &ensure_repo_created/1)

    :init.stop()
  end
  

  defp ensure_repo_created(repo) do
    case repo.__adapter__.storage_up(repo.config) do
      :ok -> :ok
      {:error, :already_up} -> :ok
      {:error, term} -> {:error, term}
    end
  end

end

and then I ran it on the pre_start hook like this:
bin/my_app command Elixir.Release.Tasks createdb,
which worked well,

now when I am using 1.9 release, i try running with

./bin/my_app eval 'Release.Tasks.createdb()'

which follows this error:

** (KeyError) key :database not found in: [telemetry_prefix: [:my_app, :repo], otp_app: :my_app, timeout: 15000, pool_size: 10]
    (elixir) lib/keyword.ex:393: Keyword.fetch!/2
    (ecto_sql) lib/ecto/adapters/postgres.ex:128: Ecto.Adapters.Postgres.storage_up/1
    lib/create_migrate_task.ex:57: Release.Tasks.ensure_repo_created/1
    (elixir) lib/enum.ex:783: Enum."-each/2-lists^foreach/1-0-"/2
    (elixir) lib/enum.ex:783: Enum.each/2
    lib/create_migrate_task.ex:18: Release.Tasks.createdb/0
    (stdlib) erl_eval.erl:680: :erl_eval.do_apply/6

note:
this is my config.exs: (I did not use run time configuration)

import Config

config :my_app,
       ecto_repos: [MyApp.Repo]

config :school, MyApp.Repo,
       database: "my-cool-db",
       password: "changeme",
       hostname: "123.456.8.789",
       port: "5432",
       timeout: 60_000,
       pool_size: 10,
       max_overflow: "100",
       queue_target: 60_000,
       queue_interval: 120_000

3 comments

#ecto #releases

2 5109 3

2024-06-17 16:01:11 UTC

Showing Posts 1 to 3

Show Best Posts
Show All (oldest first)
Show All (newest first)

LostKobrakai

Production database are most often manually created, because security is more important. At best your app doesn’t have credentials for a user, which is allowed to create databases.

Post #1

dinasol

@LostKobrakai I have a release that is deployed on various environments - dev, staging etc.. so it is necessary for me to have them created automatically on boot

here is my final code which worked well (also when having configuration in run time release.exs)

defmodule Release.Tasks do
  @moduledoc false

  @start_apps [:postgrex, :ecto, :ecto_sql]

  @myapps [:my_app]
  
  def create_and_migrate() do
    createdb()
    migrate()
  end

  def createdb do
    # Start postgrex and ecto
    IO.puts "Starting dependencies..."

    # Start apps necessary for executing migrations
    Enum.each(@start_apps, &Application.ensure_all_started/1)

    Enum.each(@myapps, &create_db_for/1)
    IO.puts "createdb task done!"

  end

  def create_db_for(app) do
    for repo <- get_repos(app) do
      :ok = ensure_repo_created(repo)
    end
  end

  defp ensure_repo_created(repo) do
    IO.puts "create #{inspect repo} database if it doesn't exist"
    case repo.__adapter__.storage_up(repo.config) do
      :ok -> :ok
      {:error, :already_up} -> :ok
      {:error, term} -> {:error, term}
    end
  end


  def migrate() do
    IO.puts "Start running migrations.."
    Enum.each(@myapps, &run_migrations_for/1)
    IO.puts "migrate task done!"
  end

  def run_migrations_for(app) do
    IO.puts "Running migrations for '#{app}'"
    for repo <- get_repos(app) do
      {:ok, _, _} = Ecto.Migrator.with_repo(repo, &Ecto.Migrator.run(&1, :up, all: true))
    end
    IO.puts "Finished running migrations for '#{app}'"
  end

  defp get_repos(app) do
    Application.load(app)
    Application.fetch_env!(app, :ecto_repos)
  end

  def rollback(repo, version) do
    {:ok, _, _} = Ecto.Migrator.with_repo(repo, &Ecto.Migrator.run(&1, :down, to: version))
  end

end

Post #2