AFAIK, matching a binary prefix is not supported with matchspecs. A couple of options I see:

1. Consider splitting postal code into two fields - the integer part and the letter suffiix. Then you could match on the exact integer part, since matching the exact binary value is supported with matchspecs.
2. Use charlists instead for the postal code, because you can match the head of a charlist, which allows you to select arbitrary prefix.
3. You could hack with comparison operators >= and < to test whether a value is greater than or equal to “12345” and less than “12346”. As far as I can tell, that might work.
4. Iterate through table records, fetch the postal code for each record, then if the code matches the required prefix fetch the desired fields.

To test what can work with matchspecs and what isn’t supported, you can play with :ets.fun2ms from the iex shell:

iex(1)> :ets.fun2ms(fn({key, "12345"} = el) -> key end)
[{{:"$1", "12345"}, [], [:"$1"]}]

iex(2)> :ets.fun2ms(fn({key, "12345" <> _} = el) -> key end)
Error: fun head contains bit syntax matching of variable '_', which cannot be translated into match_spec

A bit late with this answer, but I ran into the same problem and came up with the following solution:

defmodule Matcher do
  def match_prefix(table, part) when is_binary(part) do
    prefix = String.downcase(part) |> String.to_charlist() |> to_improper_list()
    :ets.select(table, [{{prefix, :_}, [], [:"$_"]}])
  end

  defp to_improper_list([]), do: :_   # <--- this is the main trick that causes partial matching
  defp to_improper_list([h|t]), do: [h|to_improper_list(t)]
end

1> :ets.new(:t, [:public, :named_table, :ordered_set])
2> :ets.insert(:t, [{~c"1234AB", 1}, {~c"1234AC", 2}, {~c"2345BB", 3}])
true
3> Matcher.match_prefix(:t, "1234")
[{~c"1234AB", 1}, {~c"1234AC", 2}]