How to programatically format code using plugins

mix format - reads from standard input and prints to standard output. I haven’t tested it but I suspect you can use it in conjunction with heredoc and skip the writing to stdin. If you want to batch the formatting you can first write to temporary files and format them with one call to mix format.

After a very unsucessful attempt to communicate with mix format - using Port, I ended up doing this:

  def write_and_format_module(file_path, content) do
    filename = for _ <- 1..5, into: "", do: <<Enum.random('0123456789abcdef')>>
    tmp_file = "/tmp/tmp_#{filename}.ex"
    :ok = File.write(tmp_file, content)
    System.cmd("mix", ["format", tmp_file])
    File.rename(tmp_file, file_path)
    Logger.info("Re generated: #{file_path}")
  end

You can go even simpler:

def write_and_format_module(file_path, content) do
    command = """
    mix format - <<STDIN > #{file_path}
    #{content}
    STDIN
    """
    {"", 0} = System.shell(command)
    Logger.info("Re generated: #{file_path}")
  end

awesome, thanks!

If I understand right you want to format in dev mode and therefore you can access Mix. In this case you can use this:

> iex -S mix
iex(1)> {formatter, _opts} = Mix.Tasks.Format.formatter_for_file("source.ex")
{#Function<19.89531025/1 in Mix.Tasks.Format.find_formatter_for_file/2>,
 [
   sigils: [],
   plugins: [FreedomFormatter],
   trailing_comma: true,
   inputs: ["{mix,.formatter}.exs", "{config,lib,test}/**/*.{ex,exs}"],
   locals_without_parens: [noop: 1]
 ]}
iex(2)> formatter.("""
...(2)> defmodule    Foo do
...(2)> def foo do
...(2)> noop 5
...(2)> [
...(2)> 1,
...(2)> 2,
...(2)> ]
...(2)> end
...(2)> end
...(2)> """) |> IO.puts()
defmodule Foo do
  def foo do
    noop 5

    [
      1,
      2,
    ]
  end
end

:ok

The "source.ex" given to formatter_for_file does not have to be an existing file.

Thanks! this was it

  def write_and_format_module(file_path, content) do
    :ok = file_path |> Path.dirname() |> File.mkdir_p()
    {formatter, _} = Mix.Tasks.Format.formatter_for_file("source.ex")
    File.write(file_path, formatter.(content))
    IO.puts(IO.ANSI.green() <> "* creating " <> IO.ANSI.reset() <> file_path)
  end