Mix credo complains about having more than 9 case clauses

Questions / Help
1

Hi OGs,
I have a function as follow:

defp comparing_statuses(duplicates) do
    statuses = count_duplicates_statuses(duplicates)

    case statuses do
      {"one", _, "zero", _, _, _} ->
        iterate_through_duplicates_with_status_and_remove(duplicates, "approved")

      {"one", _, "one", _, _, _} ->
        deleting_approached_and_approved_case(duplicates)

      {"two or more", _, "zero", _, _, _} ->
        accumulating_required_status(duplicates, "approved")

      {"zero", "one", _, _, _, _} ->
        iterate_through_duplicates_with_status_and_remove(duplicates, [
          "invalid",
          "under_investigation",
          "suspended"
        ])

      {"zero", "two or more", _, _, _, _} ->
        accumulating_required_status(duplicates, [
          "invalid",
          "under_investigation",
          "suspended"
        ])

      {"zero", "zero", "one", _, _, "zero"} ->
        iterate_through_duplicates_with_status_and_remove(duplicates, "approached")

      {"zero", "zero", "one", _, _, "one"} ->
        iterate_through_duplicates_with_status_and_update(
          duplicates,
          "approval_requested",
          "approved"
        )

      {"zero", "zero", "two or more", _, _, "two or more"} ->
        accumulating_required_status(duplicates, "approval_requested")

      {"zero", "zero", "two or more", _, _, "zero"} ->
        iterate_through_duplicates_with_status_and_remove(duplicates, "approached")

        handle_or_email_deletion_check(duplicates)

      {"zero", "zero", "zero", "one", _, _} ->
        iterate_through_duplicates_with_status_and_remove(duplicates, "rejected")

      {"zero", "zero", "zero", "two or more", _, _} ->
        accumulating_required_status(duplicates, "rejected")

      {"zero", "zero", "zero", "zero", "one", _} ->
        iterate_through_duplicates_with_status_and_remove(duplicates, "external")

      {"zero", "zero", "zero", "zero", "two or more", _} ->
        accumulating_required_status(duplicates, "external")

      {"zero", "zero", "zero", "zero", "zero", "two or more"} ->
        mass_deletion_check(duplicates)
    end
  end

And mix credo complains me that function is too complex (CC is 15, max is 9)

I can not break the switch case into two functions, as one function can throw an error stating that pattern is not recognised

Any ideas ?
Thank you

2

use multiple function heads

defp comparing_statuses(duplicates) do
  statuses = count_duplicates_statuses(duplicates)
  handle_statuses(statuses, duplicates)
end

defp handle_statuses(statuses, duplicates)

defp handle_statuses({"one", _, "zero", _, _, _}, duplicates),
  do: iterate_through_duplicates_with_status_and_remove(duplicates, "approved")

defp handle_statuses({"one", _, "one", _, _, _}, duplicates),
  do: deleting_approached_and_approved_case(duplicates)

  # etc.
end
6 Likes
3

I personally would just disable the Credo check, which I have done in other projects because of this. I find the multiple function clause approach too verbose in cases like this. It increases the footprint of the function with exactly duplicated information and text. In this case, the case returns are short and simple, and I would prefer case over the function clause approach here.

3 Likes
4

It’s a fair point. I read the question as “how do I re-write this”, not “how do I silence this”. Since the compiler treats the case and the multiple function clauses more or less the same way, to me this is the natural way to rewrite the code and make credo happy without touching config. What if the OP’s company requires that credo pass all checks and disabling is not allowed?

Personally, I do find the multiple function approach more readable, but it is all a matter of preference.

1 Like