Try use GenServer, restart: :transient on the GenServer module

I think you may have redacted something important, because I can’t reproduce the behavior you’re seeing. This script can be run with just elixir foo.exs:

defmodule FooSupervisor do
  use DynamicSupervisor

  def start_link(init_arg) do
    DynamicSupervisor.start_link(__MODULE__, init_arg, name: __MODULE__)
  end

  def init(:ok) do
    DynamicSupervisor.init(strategy: :one_for_one, restart: :transient)
  end

  def start_genserver() do
    spec = %{
      id: "nope",
      start: {FooWorker, :start_link, []},
      restart: :transient
    }

    IO.puts("starting child")
    DynamicSupervisor.start_child(__MODULE__, spec)
  end
end

defmodule FooWorker do
  use GenServer

  def start_link() do
    GenServer.start_link(__MODULE__, [])
  end

  @impl true
  def init(state) do
    IO.puts("child init")
    Process.send_after(self(), :terminate, 3000)
    {:ok, state}
  end

  @impl true
  def handle_info(:terminate, state) do
    IO.puts("child stop")
    {:stop, :normal, state}
  end
end

FooSupervisor.start_link(:ok)

FooSupervisor.start_genserver()

Process.sleep(:infinity)

When I run this, I get:

starting child
child init
child stop

and then nothing else.