Transpose a list of lists using list comprehension

Adapting https://stackoverflow.com/questions/5389254/transposing-a-2-dimensional-matrix-in-erlang to elixir:

defmodule Transp do
  def transpose([[] | _]), do: []
  def transpose(m) do
    [Enum.map(m, &hd/1) | transpose(Enum.map(m, &tl/1))]
  end
end

iex(2)> matrix = [[1,2],[3,4],[5,6]]
[[1, 2], [3, 4], [5, 6]]
iex(3)> Transp.transpose(matrix)
[[1, 3, 5], [2, 4, 6]]

Or simply:

iex> Enum.zip [[1,2],[3,4],[5,6]]
[{1, 3, 5}, {2, 4, 6}]

# or if you need list of lists:
iex> Enum.zip([[1,2],[3,4],[5,6]]) |> Enum.map(&Tuple.to_list/1)
[[1, 3, 5], [2, 4, 6]]

Another way (from [erlang-questions] Matrix rotator):

defmodule Transp do
  def transpose([]), do: []
  def transpose([[] | xss]), do: transpose(xss)
  def transpose([[x | xs] | xss]) do
    [[x | (for [h | _t] <- xss, do: h)] | transpose([xs | (for [_h | t] <- xss, do: t)])]
  end
end

although it’s practically the same.

If you want to shoehorn a comprehension in:

iex(1)> m = [[1,2],[3,4],[5,6]]
[[1, 2], [3, 4], [5, 6]]
iex(2)> for t <- Enum.zip(m), do: Tuple.to_list(t) 
[[1, 3, 5], [2, 4, 6]]

Personally I find the explicit map clearer.

Wow, great answers! Thank you all!