Trying to access a key inside a map

t.t

i want to access the “defaultValue” key.

%{
  "category" => {:ok,
   %{
     "defaultValue" => 10,
     "detailed" => [
       %{"categoryName" => "test", "categoryValue" => 23}
     ],
     "total" => 1
   }}
}

iex(56)> test_map["category"]
{:ok,
 %{
   "defaultValue" => 10,
   "detailed" => [%{"categoryName" => "test", "categoryValue" => 23}],
   "total" => 1
 }}

normally, i’d do this: test_map["category"]["defaultValue"]

but i get this error in return:

iex(57)> test_map["category"]["defaultValue"]
** (FunctionClauseError) no function clause matching in Access.get/3    
    
    The following arguments were given to Access.get/3:
    
        # 1
        {:ok,
         %{
           "defaultValue" => 10,
           "detailed" => [%{"categoryName" => "test", "categoryValue" => 23}],
           "total" => 1
         }}
    
        # 2
        "defaultValue"
    
        # 3
        nil
    
    Attempted function clauses (showing 5 out of 5):
    
        def get(%module{} = container, key, default)
        def get(map, key, default) when is_map(map)
        def get(list, key, default) when is_list(list) and is_atom(key)
        def get(list, key, _default) when is_list(list)
        def get(nil, _key, default)
    
    (elixir) lib/access.ex:265: Access.get/3

i noticed i have a tuple with a atom :ok and a map inside it, and that’s probably why i can’t access my “defaultValue” key but i’m new in elixir/functional programming and i am having a hard time trying to find the solution.

10 comments

#maps #ok-tuple

0 2994 10

2020-05-20 21:42:20 UTC

First 10 of 10 Posts

kokolegorille

Hello and welcome,

iex(1)> elem(test_map["category"], 1)["defaultValue"]
10

BTW it is kind of ugly to have this ok tuple inside, and I would think of reshaping the data first.

Post #1

fuelen

defaultValue can be also extracted using pattern matching

%{"category" => {:ok, %{"defaultValue" => default_value}}} = test_map
default_value # 10
# or
{:ok, category} = test_map["category"]
category["defaultValue"] # 10

However, this code will cause a runtime error if pattern doesn’t match.
If you want to handle case with error, then you should use case or with macro.

Post #2

emoragaf

I think you are looking for Kernel — Elixir v1.20.2

users = %{"john" => %{age: 27}, "meg" => %{age: 23}}
get_in(users, ["john", :age])
27

Post #3

benwilson512

Author of Craft GraphQL APIs in Elixir with Absinthe

This won’t help on its own, he has a tuple in there.

Post #4

t.t

how would you reshape it?

Post #5

t.t

is there any way that i can take the tuple + atom off my map?

go to this:

%{
  "category" => 
   %{
     "defaultValue" => 10,
     "detailed" => [
       %{"categoryName" => "test", "categoryValue" => 23}
     ],
     "total" => 1
   }}

Post #6

kokolegorille

Yes You can…

I would say FP is made of pipeline of transformation.

Enum.reduce test_map, %{}, fn {k, {:ok, v}}, acc -> Map.put(acc, k, v) end

Post #7

benwilson512

Author of Craft GraphQL APIs in Elixir with Absinthe

Where does the data come from? It looks like this is a data structure you built right?

Post #8

t.t

it worked! thank you!

Post #9

emoragaf

I totally missed the tuple, but you can use the get_in ability to pass functions to handle the tuples

map = %{
  "category" => {:ok,
   %{
     "defaultValue" => 10,
     "detailed" => [
       %{"categoryName" => "test", "categoryValue" => 23}
     ],
     "total" => 1
   }}
}
cleaned_map = %{
  "category" =>%{
     "defaultValue" => 10,
     "detailed" => [
       %{"categoryName" => "test", "categoryValue" => 23}
     ],
     "total" => 1
   }
}

# get the value if its a tuple
val = fn :get, {:ok, v}, next -> next.(v)
          :get, data, next -> next.(data) end
# It works on the original map
get_in(map, ["category", val, "defaultValue"])
|> IO.inspect
# 10

# Also works on a preprocessed map
get_in(cleaned_map, ["category", val, "defaultValue"])
|> IO.inspect
# 10

Post #10

— All posts loaded —