Using Application.get_env / Application.put_env in ExUnit tests

phtrivier

Should it be safe to use Application put/get env in multiple tests ?
Assuming I “clean” the env at the setup of each tests, is it possible that env “leaks” between tests ?
For example this seems to work, but is there any guarantee that it won’t fail once in a blue moon ?

defmodule SUT do
   def act() do
      x = Application.get_env(:app, :params)[:x]
      # .... Use x for whatever 
   end
end

defmodule Case1 do 
  use ExUnit.Case

  setup do 
    Application.put_env(:app, :params, x: nil)
  end

  test "Code that needs x to be 0" do
    Application.put_env(:app, :params, x: 0)
    SUT.act()
  end

  test "Code that needs x to be 1" do
    Application.put_env(:app, :params, x: 1)
    SUT.act()
  end
end

defmodule Case2 do 
  use ExUnit.Case

  setup do 
    Application.put_env(:app, :params, x: nil)
  end

  test "Code that needs x to be 3" do
    Application.put_env(:app, :params, x: 3)
    SUT.act()
  end
end

(In particular, I’m not clear about whetever a Process is run for each test, for each case, etc… and how it might interact with Application config…)

4 comments

#testing

0 9047 4

2025-01-08 16:52:37 UTC

Showing Posts 1 to 4

Show Best Posts
Show All (oldest first)
Show All (newest first)

hubertlepicki

This will break as soon as you use async: true in your tests. Which may or may not be a problem for you.

You probably also want to do the cleanup after the tests, not before. If the tests run in random order, they will jump to some other test file after these tests are done, and the variables may be affecting the behavior in other tests. If you do the cleanups in setup blocks executed before each test here, you want to do it in other test files as well. Otherwise weird things will happen.

Alternative to this is to clean up in on_exit callback: ExUnit.Callbacks — ExUnit v1.20.2

So you can go with what you have provided:

the tests are async: false
the cleanup is done in on_exit block

Post #1

jtompl

If you want a code example for the above, it would be like this:

defmodule MyTest do
  use ExUnit.Case, async: false

  setup do
    put_application_env_for_test(:some_app, :some_key, :some_value)
  end

  defp put_application_env_for_test(app, key, value) do
    previous_value = Application.get_env(app, key)
    Application.put_env(app, key, value)
    on_exit(fn -> Application.put_env(app, key, previous_value) end)
  end
end

Post #2

soyjeansoy

Wow this solved my problem!

Post #3

axelson

Scenic Core Team

If you use ProcessTree then you can effectively modify the application environment for most processes while keeping the ability to use async: true tests. It works by looking for env first in the process dictionary of the current process, and then the dictionary of all ancestor and caller processes:

https://github.com/jbsf2/process-tree

I’ve been using it quite a bit and it’s a really nice way to allow using the application environment while still using async: true.

Post #4

— All posts loaded —