Why Phoenix Recycling?

chensan

I’m writing tests for my controller:

  defp log_in_user(%{conn: conn, log_in_as: email}) do
    role = role_fixture()
    user = user_fixture(role, email: email)
    conn = assign(conn, :current_user, user)
    {:ok, conn: conn, user: user}
  end

  defp create_site(%{conn: conn, user: user}) do
    site = site_fixture(user)
    {:ok, site: site}
  end

  describe "delete site" do
    setup [:log_in_user, :create_site]

    @tag log_in_as: "sam"
    test "deletes chosen site", %{conn: conn, site: site} do
      conn = delete(conn, Routes.site_path(conn, :delete, site))
      assert redirected_to(conn) == Routes.site_path(conn, :index)

      assert_error_sent 404, fn ->
        get(conn, Routes.site_path(conn, :show, site))
      end
    end
  end

The weird thing here is conn.assigns.current_user becomes nil in assert_error_sent where it should have value.

I found some similar questions around the web:

Seems the problem is caused by Phoenix.ConnTest – Phoenix v1.4.0, and there’s a fix:

      saved_assigns = conn.assigns

      conn =
        conn
        |> recycle()
        |> Map.put(:assigns, saved_assigns)

I don’t quite understand why, it’s so unexpected in our tests. Anyone could help explain it?

8 comments

/phoenix #testing

1 2862 8

2018-11-27 16:52:07 UTC

Showing Posts 1 to 8

Show Best Posts
Show All (oldest first)
Show All (newest first)

LostKobrakai

recycle does essentially what happens if you start a new request in the browser. Any new request in the browser will start of without any assigns. Usually you’re kept logged in by putting something in the session for the user.

Post #1

chensan

When I logged in a website, I would expect myself logged-in all the time until I log out. But Phoenix recycling breaks this expectation.

Post #2

LostKobrakai

That’s just not true. If you’re not using session based authentication you’d need to log in new for each request. The only data which survives between requests is the stuff you put into the session. Anything else is discarded at the end of a request. That’s true for the request you do with a browser in dev mode and exactly what recycle mimics for tests.

Post #3

chensan

Ok, so how can I make the tests better? Writing conn = conn |> cycle() |> Map.put(:assigns, conn.assigns) everywhere in my controller tests is so ugly.

Post #4

idi527

Maybe Plug.Test — Plug v1.20.2

setup %{conn: conn} do
  {:ok, conn: Plug.Test.init_test_session(conn, user_id: 666)}
end

I wouldn’t change assigns manually, instead I’d pipe the requests through the actual plug pipelines with the session set via Plug.Test.init_test_session/2 to get the expected conn with all relevant assigns set.

Post #5

LostKobrakai

Either what @idi527 said: Use the session and your real plugs / pipelines.
Or simply not reuse the conn for places where you’re e.g. testing a single plug.

result = MyPlug.call(conn, opts)
assert …

result = MyPlug.call(conn, opts_2)
assert …

Post #6

chensan

Can we say the tip presented in Programming Phoenix book for easier testing is defective

  def call(conn, _opts) do
    user_id = get_session(conn, :user_id)

    cond do
      conn.assigns[:current_user] ->
        conn

      user = user_id && Accounts.get_user(user_id) ->
        assign(conn, :current_user, user)

      true ->
        assign(conn, :current_user, nil)
    end
  end

In the beginning I just logged in user with naive post(conn, Routes.session_path(conn, :create), ...):

    @tag log_in_as: "sam"
    test "deletes chosen site", %{conn: conn, site: site, user: user} do
      conn =
        post(conn, Routes.session_path(conn, :create),
          session: %{email: user.email, password: "123456"}
        )

      conn = delete(conn, Routes.site_path(conn, :delete, site))
      assert redirected_to(conn) == Routes.site_path(conn, :index)

      # conn =
      #   conn
      #   |> recycle()
      #   |> Map.put(:assigns, conn.assigns)

      assert_error_sent 404, fn ->
        get(conn, Routes.site_path(conn, :show, site))
      end
    end

No need to call recycle() in this code.

Post #7

chensan

After reading the source code, I’d like to share what I learned so far.

When we run get(conn, Routes.site_path(conn, :show, site)), a new conn was created, and cookies and some request headers (~w(accept authorization)) from old conn are copied to new conn - that’s what Phoenix recycling does for us, it emulates the behavior of browser. But conn.assigns is not copied, results in a nil value of current_user.

The reason post(conn, Routes.session_path(conn, :create), session: %{email: user.email, password: "123456"} ) works is because Auth module selects another path:

  def call(conn, _opts) do
    user_id = get_session(conn, :user_id)

    cond do
      conn.assigns[:current_user] -> # <- the way programming phoenix book suggests
        conn

      user = user_id && Accounts.get_user(user_id) -> # <- post Routes.session_path just selects this way.
        assign(conn, :current_user, user)

      true ->
        assign(conn, :current_user, nil)
    end
  end

Thanks all for your kind help

Post #8

— All posts loaded —