Zing, basic Elixir ICMP ('ping') server using Zig NIF

Actually since OTP 22.3 you can use socket module to have ICMP socket. If you want to use raw socket however you will need to be superuser, but Darwin and Linux supports ICMP over dgram sockets.

To prove that it is possible:

defmodule GenICMP do
  @data <<0xdeadbeef::size(32)>>
  def ping(addr) do
    {:ok, s} = open()

    data = @data

    req_echo(s, addr, data: data)

    case recv_echo(s) do
      {:ok, %{data: ^data}} = resp -> resp
      {:ok, other} -> {:error, other}
      _ -> {:error, :invalid_resp}
    end
  end

  def open, do: :socket.open(:inet, :dgram, :icmp)

  def req_echo(socket, addr, opts \\ []) do
    data = Keyword.get(opts, :data, @data)
    id = Keyword.get(opts, :id, 0)
    seq = Keyword.get(opts, :seq, 0)

    sum = checksum(<<8, 0, 0::size(16), id, seq, data::binary>>)

    msg = <<8, 0, sum::binary, id, seq, data::binary>>

    :socket.sendto(socket, msg, %{family: :inet, port: 1, addr: addr})
  end

  def recv_echo(socket, timeout \\ 5000) do
    {:ok, data} = :socket.recv(socket, 0, [], timeout)

    <<_::size(160), pong::binary>> = data

    case pong do
      <<0, 0, _::size(16), id, seq, data::binary>> ->
        {:ok, %{
          id: id, seq: seq, data: data
        }}
      _ -> {:error, pong}
    end
  end

  defp checksum(bin), do: checksum(bin, 0)

  defp checksum(<<x::integer-size(16), rest::binary>>, sum), do: checksum(rest, sum + x)
  defp checksum(<<x>>, sum), do: checksum(<<>>, sum + x)
  defp checksum(<<>>, sum) do
    <<x::size(16), y::size(16)>> = <<sum::size(32)>>

    res = :erlang.bnot(x + y)

    <<res::big-size(16)>>
  end
end

API is simple:

GenICMP.ping({127, 0, 0, 1})

Tested on macOS, but should work on Linux as well. I am not sure about BSDs.

EDIT:

Just in case, this project seems as a good example of how to use Zigler to write Erlang NIFs, and it is great. However sending ICMP echo requests via socket is absolutely possible.

Lol, I tried this two months ago and support for the :icmp mode wasn’t there!! I think I was on 22.2, and I asked Peter dimitrov at codebeam and he said they weren’t going to do icmp

I was trying to implement gen_icmp earlier via socket and encountered that problem. So instead I created PR to the core that fixed checks for {type, proto} pairs and now it is possible to create such socket. I think that he meant that they will not implement ICMP helper function directly in OTP, but manual implementation via socket should be possible (on supporting OSes, as traditionally ICMP sockets needed to be created as raw sockets which can be created only by superuser).

Yeah. We must have been in the same place because I remember looking through the :socket nif code and scratching my head about some dead ends. However I’m not brave enough to figure out how to do full otp/erlang build to make PRs to core. Maybe I should work on that.

I think he must have misinterpreted my question. It was over the vtc after all.

Do you think your code above should be a library?

I can clean it up and make it into library later.

Happy to help if you’d like some!

I have implemented ICMP, but ICMPv6 is still not done, if you want then I would be glad for PR. It uses slightly different API from what You are using as I wanted something “more basic” so users could build larger functionalities on top of this.

From different tests I made on macOS and Linux, it looks like macOS needs us to compute the checksum for the echo request and then give us back the full IP packet of the echo reply, hence your _::size(160) to skip 20 bytes of IP header. On Linux we do not need to compute the checksum or set an id because the OS will dot it for us and we also only get the ICMP echo reply, not the full IP packet.

This is confirmed by the ping source code on MacOS. I guess the behaviour of the library regarding a socket created with socket(PF_INET, SOCK_DGRAM, IPPROTO_ICMP) is quite OS dependent.

You might want to try this: API Reference — icmp v0.1.0