Post request got an InvalidBody error

I created a post request (localhost:4000/api/students/)

Headers:
‘Accept: application/vnd.api+json’
‘Content-Type: application/vnd.api+json’

Body:

{
  "data": {
    "type": "student",
    "attributes": {
      "first_name": "some name",
      "last_name": "last name"
    }
  }
}

I got an error InvalidBody

{
    "errors": [
        {
            "code": "invalid_body",
            "id": "a174c29e-5ffe-4cf4-b4a4-97a67f6e65aa",
            "meta": {},
            "status": "400",
            "title": "InvalidBody",
            "source": {
                "pointer": "data/attributes/last_name"
            },
            "detail": "Expected only defined properties, got key [\"data\", \"attributes\", \"last_name\"]."
        },
        {
            "code": "invalid_body",
            "id": "a6408d19-4271-4753-b86a-134fd009af93",
            "meta": {},
            "status": "400",
            "title": "InvalidBody",
            "source": {
                "pointer": "data/attributes/first_name"
            },
            "detail": "Expected only defined properties, got key [\"data\", \"attributes\", \"first_name\"]."
        }
    ],
    "jsonapi": {
        "version": "1.0"
    }
}

How does your resouce look like?

defmodule MyApp.Students do
  use Ash.Domain, extensions: [AshJsonApi.Domain]

  authorization do
    authorize :by_default
  end

  resources do
    resource MyApp.Students.Student
  end
end
defmodule MyApp.Students.Student do
  use Ash.Resource,
    domain: MyApp.Students,
    data_layer: AshPostgres.DataLayer,
    extensions: [
      AshJsonApi.Resource
    ]

  json_api do
    type "student"

    routes do
      base("/students")

      get(:stud, route: "/student")
      index :read
      post(:create)
      patch(:update)
      delete(:destroy)
      get(:login)
    end
  end

  actions do
    read :read do
      primary? true
    end

    create :create
    update :update
    destroy :destroy
  end

  postgres do
    table "students"
    repo MyApp.Repo
  end

  attributes do
    uuid_primary_key :id

    attribute :first_name, :string do
      allow_nil? false
    end

    attribute :last_name, :string do
      allow_nil? false
    end

    create_timestamp :inserted_at
    update_timestamp :updated_at
  end
end

Two things:

First, The reason for this specific error is that the first and last name are not accepted by the actions. You probably want:


create :create do
  accept [:first_name, :last_name]
end

update :update do
  accept [:first_name, :last_name]
end

second, you likely want to make the first and last name attributes public? so that they display in the API.

2 Likes

Thanks, @zachdaniel @kamaroly, It works good.

1 Like

The following should also work.

  actions do
    # ========Add this line============
    default_accept  [:first_name, :last_name]
  end
1 Like