Unfortunately an overriding implementation will not work because Elixir does not support overriding protocols. Here is a similar case to yours.

You would need to create a wrapper struct and then create an Jason.Encoder implementation for it. For example:

defmodule MyApp.TzDateTime do
  @type t :: %__MODULE__{value: DateTime.t()}

  @enforce_keys :value
  defstruct value: nil

  @spec new(DateTime.t() | NaiveDateTime.t()) :: t()
  def new(%DateTime{} = value) do
    %__MODULE__{value: value}
  end

  def new(%NaiveDateTime{} = value) do
    %__MODULE__{value: DateTime.from_naive!(value, "Etc/UTC")}
  end

  defimpl Jason.Encoder do
    def encode(%MyApp.TzDateTime{value: value}, _opts), do: DateTime.to_iso8601(value)
  end
end

And on your Phoenix view that renders the JSON:

defmodule MyApp.MyStuffView do
  use MyApp, :view

  def render("index.json", %{mystuffs: mystuffs}) do
    %{data: render_many(mystuffs, MyApp.MyStuffView, "mystuff.json")}
  end

  def render("show.json", %{mystuff: mystuff}) do
    %{data: render_one(mystuff, MyApp.MyStuffView, "mystuff.json")}
  end

  def render("mystuff.json", %{mystuff: mystuff}) do
    %{date: MyApp.TzDateTime.new(Mystuff.my_date_field)}
  end
end