Mapping/transforming user input from a form that does not directly map to a schema?

Hi

Ecto Type looks like a good fit for this case. The advantage of it is that is pluggable so you use it on similar fields if you need.

defmodule PriceType do
  use Ecto.Type

  def type, do: :integer

  def cast(%{unit: unit, cents: cents}) do
    {:ok, to_price(unit, cents)}
  end

  # This handle params that comes directly from Phoenix controllers or LiveView.
  def cast(%{"unit" => unit, "cents" => cents}) do
    {:ok, to_price(unit, cents)}
  end

  def cast(price) when is_integer(price) do
    {:ok, price}
  end

  def cast(_), do: :error

  # You might need to handle more cases when unit and cents are not binary.
  defp to_price(unit, cents) when is_binary(unit) and is_binary(cents) do
    String.to_integer(unit <> cents)
  end

  defp to_price(unit, cents) do
    raise "#{unit} and #{cents} are not Strings"
  end

  def load(price) when is_integer(price), do: {:ok, price}

  def dump(price), do: {:ok, price}
end

Other options would be doing it on the changeset level or even on the controller/Live view layer. It really depends on how you want/prefer this data to passed around in your application.

People also like to use Decimal — Decimal v3.1.1 to handle it and there is also this library that you can take some inspiration GitHub - elixirmoney/money: Elixir library for working with Money safer, easier, and fun... Is an interpretation of the Fowler's Money pattern in fun.prog. · GitHub.

It also common to use Money masks on User inputs so that the value comes to your back-end as: $1000,20. This is doable in the same Ecto Type above just adding a new clause to cast/1