How to access schema information during Ecto query generation when using Absinthe/Dataloader?

Hi, I’m using Absinthe with Dataloader and have a question.

Here’s some code that mimics the example from the tutorial very closely (found here), all the usual suspects:

defmodule MyApp.Schema do
  # ...
  object :post do
    field :title, :string
  end

  object :author do
    field :posts, list_of(:post) do
      arg(:limit, :integer)
      resolve(dataloader(MyApp.Blog))
    end
  end

  def context(ctx) do
    loader =
      Dataloader.new()
      |> Dataloader.add_source(MyApp.Blog, MyApp.Blog.data())

    Map.put(ctx, :loader, loader)
  end

  def plugins do
    [Absinthe.Middleware.Dataloader] ++ Absinthe.Plugin.defaults()
  end
end

And then MyApp.Blog:

defmodule MyApp.Blog do
  # ...
  def data() do
    Dataloader.Ecto.new(MyApp.Repo, query: &query/2)
  end

  def query(queryable, params) do
    # How can I get params[:limit] to be the :limit arg from the schema???
    queryable
    |> limit(params[:limit] || 20)
  end
end

My question is: how can I access the limit arg attached to the posts field on author from the Schema, such that I can use an Ecto limit query inside MyApp.Blog.query/2? I can see in the docs that you can pass params along to the query function by passing them along in the Dataloader.load call, but from what I can tell, that is called internally.

Is there a way to pass the limit arg through that doesn’t involve abandoning dataloader and falling back to the raw batch function?

Thanks for any help!

Hey @pwightman. To start with, the load function is not private or internal, it’s the main API for Dataloader itself. The dataloader/1 helper is great, and covers a lot of main use cases, but in certain complex scenarios using load/4 directly is perfectly fine.

The dataloader/1 helper actually passes along all arguments the resolver has to the query function, so you should actually see limit in there already, have you looked for it?

Unfortunately though, using a limit here is probably not what you want. limit when applied to an SQL query applies to the total number of result rows, whereas the meaning or authors { posts(limit: 20) } would normally be “20 posts per author”.

To limit the way you want requires window functions, which are not yet supported out of the box by dataloader. You can find some discussion of this here: https://github.com/absinthe-graphql/absinthe_relay/issues/128 This is specifically about relay connection queries but the principle is the same.

3 Likes

Ah, very true. Mostly I was using this as an example of passing arbitrary values to fields, accessing the schema generally, etc, but I had forgotten about this issue with limit specifically.

I feel a little like I’m going crazy, but yes, it turns out query/2 does receive all args already, I checked this specifically last night before posting and could have sworn it wasn’t, but upon checking again this morning, there they are.

Digging a bit, I was also happy to find there’s a dataloader/3 with all sorts of useful information in it as well, so should be able to access everything I need.

Thanks for all your work on Absinthe, really enjoying it!

2 Likes